Removed bundle_consider, and plugins: buffergator and fuzzyfinder (+l9). Give

a try to ctrlp plugin.

bundle/git_ctrlp/autoload/ctrlp/buffertag.vim

@@ -0,0 +1,234 @@
+" =============================================================================
+" File:          autoload/ctrlp/buffertag.vim
+" Description:   Buffer Tag extension
+" Maintainer:    Kien Nguyen <github.com/kien>
+" Credits:       Much of the code was taken from tagbar.vim by Jan Larres, plus
+"                a few lines from taglist.vim by Yegappan Lakshmanan and from
+"                buffertag.vim by Takeshi Nishida.
+" =============================================================================
+
+" Init {{{1
+if exists('g:loaded_ctrlp_buftag') && g:loaded_ctrlp_buftag
+	fini
+en
+let g:loaded_ctrlp_buftag = 1
+
+let s:buftag_var = {
+	\ 'init': 'ctrlp#buffertag#init(s:crfile)',
+	\ 'accept': 'ctrlp#buffertag#accept',
+	\ 'lname': 'buffer tags',
+	\ 'sname': 'bft',
+	\ 'exit': 'ctrlp#buffertag#exit()',
+	\ 'type': 'tabs',
+	\ }
+
+let g:ctrlp_ext_vars = exists('g:ctrlp_ext_vars') && !empty(g:ctrlp_ext_vars)
+	\ ? add(g:ctrlp_ext_vars, s:buftag_var) : [s:buftag_var]
+
+let s:id = g:ctrlp_builtins + len(g:ctrlp_ext_vars)
+
+fu! s:opts()
+	let opts = {
+		\ 'g:ctrlp_buftag_systemenc': ['s:enc', &enc],
+		\ 'g:ctrlp_buftag_ctags_bin': ['s:bin', ''],
+		\ 'g:ctrlp_buftag_types': ['s:usr_types', ''],
+		\ }
+	for [ke, va] in items(opts)
+		exe 'let' va[0] '=' string(exists(ke) ? eval(ke) : va[1])
+	endfo
+endf
+cal s:opts()
+
+fu! s:bins()
+	let bins = [
+		\ 'ctags-exuberant',
+		\ 'exuberant-ctags',
+		\ 'exctags',
+		\ '/usr/local/bin/ctags',
+		\ '/opt/local/bin/ctags',
+		\ 'ctags',
+		\ 'ctags.exe',
+		\ 'tags',
+		\ ]
+	if empty(s:bin)
+		for bin in bins | if executable(bin)
+			let s:bin = bin
+			brea
+		en | endfo
+	el
+		let s:bin = expand(s:bin, 1)
+	en
+endf
+cal s:bins()
+
+" s:types {{{2
+let s:types = {
+	\ 'asm'    : '%sasm%sasm%sdlmt',
+	\ 'aspperl': '%sasp%sasp%sfsv',
+	\ 'aspvbs' : '%sasp%sasp%sfsv',
+	\ 'awk'    : '%sawk%sawk%sf',
+	\ 'beta'   : '%sbeta%sbeta%sfsv',
+	\ 'c'      : '%sc%sc%sdgsutvf',
+	\ 'cpp'    : '%sc++%sc++%snvdtcgsuf',
+	\ 'cs'     : '%sc#%sc#%sdtncEgsipm',
+	\ 'cobol'  : '%scobol%scobol%sdfgpPs',
+	\ 'eiffel' : '%seiffel%seiffel%scf',
+	\ 'erlang' : '%serlang%serlang%sdrmf',
+	\ 'expect' : '%stcl%stcl%scfp',
+	\ 'fortran': '%sfortran%sfortran%spbceiklmntvfs',
+	\ 'html'   : '%shtml%shtml%saf',
+	\ 'java'   : '%sjava%sjava%spcifm',
+	\ 'javascript': '%sjavascript%sjavascript%sf',
+	\ 'lisp'   : '%slisp%slisp%sf',
+	\ 'lua'    : '%slua%slua%sf',
+	\ 'make'   : '%smake%smake%sm',
+	\ 'pascal' : '%spascal%spascal%sfp',
+	\ 'perl'   : '%sperl%sperl%sclps',
+	\ 'php'    : '%sphp%sphp%scdvf',
+	\ 'python' : '%spython%spython%scmf',
+	\ 'rexx'   : '%srexx%srexx%ss',
+	\ 'ruby'   : '%sruby%sruby%scfFm',
+	\ 'scheme' : '%sscheme%sscheme%ssf',
+	\ 'sh'     : '%ssh%ssh%sf',
+	\ 'csh'    : '%ssh%ssh%sf',
+	\ 'zsh'    : '%ssh%ssh%sf',
+	\ 'slang'  : '%sslang%sslang%snf',
+	\ 'sml'    : '%ssml%ssml%secsrtvf',
+	\ 'sql'    : '%ssql%ssql%scFPrstTvfp',
+	\ 'tcl'    : '%stcl%stcl%scfmp',
+	\ 'vera'   : '%svera%svera%scdefgmpPtTvx',
+	\ 'verilog': '%sverilog%sverilog%smcPertwpvf',
+	\ 'vim'    : '%svim%svim%savf',
+	\ 'yacc'   : '%syacc%syacc%sl',
+	\ }
+
+cal map(s:types, 'printf(v:val, "--language-force=", " --", "-types=")')
+
+if executable('jsctags')
+	cal extend(s:types, { 'javascript': { 'args': '-f -', 'bin': 'jsctags' } })
+en
+
+if type(s:usr_types) == 4
+	cal extend(s:types, s:usr_types)
+en
+" Utilities {{{1
+fu! s:validfile(fname, ftype)
+	if ( !empty(a:fname) || !empty(a:ftype) ) && filereadable(a:fname)
+		\ && index(keys(s:types), a:ftype) >= 0 | retu 1 | en
+	retu 0
+endf
+
+fu! s:exectags(cmd)
+	if exists('+ssl')
+		let [ssl, &ssl] = [&ssl, 0]
+	en
+	if &sh =~ 'cmd\.exe'
+		let [sxq, &sxq, shcf, &shcf] = [&sxq, '"', &shcf, '/s /c']
+	en
+	let output = system(a:cmd)
+	if &sh =~ 'cmd\.exe'
+		let [&sxq, &shcf] = [sxq, shcf]
+	en
+	if exists('+ssl')
+		let &ssl = ssl
+	en
+	retu output
+endf
+
+fu! s:exectagsonfile(fname, ftype)
+	let [ags, ft] = ['-f - --sort=no --excmd=pattern --fields=nKs ', a:ftype]
+	if type(s:types[ft]) == 1
+		let ags .= s:types[ft]
+		let bin = s:bin
+	elsei type(s:types[ft]) == 4
+		let ags = s:types[ft]['args']
+		let bin = expand(s:types[ft]['bin'], 1)
+	en
+	if empty(bin) | retu '' | en
+	let cmd = s:esctagscmd(bin, ags, a:fname)
+	if empty(cmd) | retu '' | en
+	let output = s:exectags(cmd)
+	if v:shell_error || output =~ 'Warning: cannot open' | retu '' | en
+	retu output
+endf
+
+fu! s:esctagscmd(bin, args, ...)
+	if exists('+ssl')
+		let [ssl, &ssl] = [&ssl, 0]
+	en
+	let fname = a:0 == 1 ? shellescape(a:1) : ''
+	let cmd = shellescape(a:bin).' '.a:args.' '.fname
+	if exists('+ssl')
+		let &ssl = ssl
+	en
+	if has('iconv')
+		let last = s:enc != &enc ? s:enc : !empty($LANG) ? $LANG : &enc
+		let cmd = iconv(cmd, &enc, last)
+	en
+	retu cmd
+endf
+
+fu! s:process(fname, ftype)
+	if !s:validfile(a:fname, a:ftype) | retu [] | endif
+	let ftime = getftime(a:fname)
+	if has_key(g:ctrlp_buftags, a:fname)
+		\ && g:ctrlp_buftags[a:fname]['time'] >= ftime
+		let lines = g:ctrlp_buftags[a:fname]['lines']
+	el
+		let data = s:exectagsonfile(a:fname, a:ftype)
+		let [raw, lines] = [split(data, '\n\+'), []]
+		for line in raw | if len(split(line, ';"')) == 2
+			let parsed_line = s:parseline(line)
+			if parsed_line != ''
+				cal add(lines, parsed_line)
+			en
+		en | endfo
+		let cache = { a:fname : { 'time': ftime, 'lines': lines } }
+		cal extend(g:ctrlp_buftags, cache)
+	en
+	retu lines
+endf
+
+fu! s:parseline(line)
+	let eval = '\v^([^\t]+)\t(.+)\t\/\^(.+)\$\/\;\"\t(.+)\tline(no)?\:(\d+)'
+	let vals = matchlist(a:line, eval)
+	if empty(vals) | retu '' | en
+	let [bufnr, bufname] = [bufnr('^'.vals[2].'$'), fnamemodify(vals[2], ':p:t')]
+	retu vals[1].'	'.vals[4].'|'.bufnr.':'.bufname.'|'.vals[6].'| '.vals[3]
+endf
+" Public {{{1
+fu! ctrlp#buffertag#init(fname)
+	let fname = exists('s:bufname') ? s:bufname : a:fname
+	let bufs = exists('s:btmode') && s:btmode ? ctrlp#allbufs() : [fname]
+	let lines = []
+	for each in bufs
+		let tftype = get(split(getbufvar(each, '&ft'), '\.'), 0, '')
+		cal extend(lines, s:process(each, tftype))
+	endfo
+	if !hlexists('CtrlPTabExtra')
+		hi link CtrlPTabExtra Comment
+	en
+	sy match CtrlPTabExtra '\zs\t.*\ze$'
+	retu lines
+endf
+
+fu! ctrlp#buffertag#accept(mode, str)
+	let vals = matchlist(a:str, '\v^[^\t]+\t+[^\t|]+\|(\d+)\:[^\t|]+\|(\d+)\|')
+	let [bufnm, linenr] = [fnamemodify(bufname(str2nr(vals[1])), ':p'), vals[2]]
+	cal ctrlp#acceptfile(a:mode, bufnm, linenr)
+endf
+
+fu! ctrlp#buffertag#cmd(mode, ...)
+	let s:btmode = a:mode
+	if a:0 && !empty(a:1)
+		let s:bufname = fnamemodify(a:1, ':p')
+	en
+	retu s:id
+endf
+
+fu! ctrlp#buffertag#exit()
+	unl! s:btmode s:bufname
+endf
+"}}}
+
+" vim:fen:fdm=marker:fmr={{{,}}}:fdl=0:fdc=1:ts=2:sw=2:sts=2

bundle/git_ctrlp/autoload/ctrlp/dir.vim

@@ -0,0 +1,93 @@
+" =============================================================================
+" File:          autoload/ctrlp/dir.vim
+" Description:   Directory extension
+" Author:        Kien Nguyen <github.com/kien>
+" =============================================================================
+
+" Init {{{1
+if exists('g:loaded_ctrlp_dir') && g:loaded_ctrlp_dir
+	fini
+en
+let [g:loaded_ctrlp_dir, g:ctrlp_newdir] = [1, 0]
+
+let s:ars = [
+	\ 's:maxdepth',
+	\ 's:maxfiles',
+	\ 's:compare_lim',
+	\ 's:glob',
+	\ ]
+
+let s:dir_var = {
+	\ 'init': 'ctrlp#dir#init('.join(s:ars, ', ').')',
+	\ 'accept': 'ctrlp#dir#accept',
+	\ 'lname': 'dirs',
+	\ 'sname': 'dir',
+	\ 'type': 'path',
+	\ }
+
+let g:ctrlp_ext_vars = exists('g:ctrlp_ext_vars') && !empty(g:ctrlp_ext_vars)
+	\ ? add(g:ctrlp_ext_vars, s:dir_var) : [s:dir_var]
+
+let s:id = g:ctrlp_builtins + len(g:ctrlp_ext_vars)
+" Utilities {{{1
+fu! s:globdirs(dirs, depth)
+	let entries = split(globpath(a:dirs, s:glob), "\n")
+	let [dirs, depth] = [ctrlp#dirnfile(entries)[0], a:depth + 1]
+	cal extend(g:ctrlp_alldirs, dirs)
+	if !empty(dirs) && !s:max(len(g:ctrlp_alldirs), s:maxfiles)
+		\ && depth <= s:maxdepth
+		sil! cal ctrlp#progress(len(g:ctrlp_alldirs))
+		cal s:globdirs(join(dirs, ','), depth)
+	en
+endf
+
+fu! s:max(len, max)
+	retu a:max && a:len > a:max ? 1 : 0
+endf
+" Public {{{1
+fu! ctrlp#dir#init(...)
+	let s:cwd = getcwd()
+	for each in range(len(s:ars))
+		exe 'let' s:ars[each] '=' string(eval('a:'.(each + 1)))
+	endfo
+	let cadir = ctrlp#utils#cachedir().ctrlp#utils#lash().s:dir_var['sname']
+	let cafile = cadir.ctrlp#utils#lash().ctrlp#utils#cachefile(s:dir_var['sname'])
+	if g:ctrlp_newdir || !filereadable(cafile)
+		let g:ctrlp_alldirs = []
+		cal s:globdirs(s:cwd, 0)
+		cal ctrlp#rmbasedir(g:ctrlp_alldirs)
+		let read_cache = 0
+		if len(g:ctrlp_alldirs) <= s:compare_lim
+			cal sort(g:ctrlp_alldirs, 'ctrlp#complen')
+		en
+	el
+		let g:ctrlp_alldirs = ctrlp#utils#readfile(cafile)
+		let read_cache = 1
+	en
+	if !read_cache
+		cal ctrlp#utils#writecache(g:ctrlp_alldirs, cadir, cafile)
+		let g:ctrlp_newdir = 0
+	en
+	retu g:ctrlp_alldirs
+endf
+
+fu! ctrlp#dir#accept(mode, str)
+	let path = a:mode == 'h' ? getcwd() : s:cwd.ctrlp#utils#lash().a:str
+	if a:mode =~ 't\|v\|h'
+		cal ctrlp#exit()
+	en
+	cal ctrlp#setdir(path, a:mode =~ 't\|h' ? 'chd!' : 'lc!')
+	if a:mode == 'e'
+		sil! cal ctrlp#statusline()
+		cal ctrlp#setlines(s:id)
+		cal ctrlp#recordhist()
+		cal ctrlp#prtclear()
+	en
+endf
+
+fu! ctrlp#dir#id()
+	retu s:id
+endf
+"}}}
+
+" vim:fen:fdm=marker:fmr={{{,}}}:fdl=0:fdc=1:ts=2:sw=2:sts=2

bundle/git_ctrlp/autoload/ctrlp/line.vim

@@ -0,0 +1,67 @@
+" =============================================================================
+" File:          autoload/ctrlp/line.vim
+" Description:   Line extension - Find a line in any buffer
+" Author:        Kien Nguyen <github.com/kien>
+" =============================================================================
+
+" User Configuration {{{1
+" Enable:
+"        let g:ctrlp_extensions += ['line']
+" Create A Command:
+"        com! CtrlPLine cal ctrlp#init(ctrlp#line#id())
+"}}}
+
+" Init {{{1
+if exists('g:loaded_ctrlp_line') && g:loaded_ctrlp_line
+	fini
+en
+let g:loaded_ctrlp_line = 1
+
+let s:line_var = {
+	\ 'init': 'ctrlp#line#init()',
+	\ 'accept': 'ctrlp#line#accept',
+	\ 'lname': 'lines',
+	\ 'sname': 'lns',
+	\ 'type': 'tabe',
+	\ }
+
+let g:ctrlp_ext_vars = exists('g:ctrlp_ext_vars') && !empty(g:ctrlp_ext_vars)
+	\ ? add(g:ctrlp_ext_vars, s:line_var) : [s:line_var]
+
+let s:id = g:ctrlp_builtins + len(g:ctrlp_ext_vars)
+" Public {{{1
+fu! ctrlp#line#init()
+	let [bufs, lines] = [ctrlp#allbufs(), []]
+	for each in bufs
+		let from_file = readfile(each)
+		cal map(from_file, 'tr(v:val, ''	'', '' '')')
+		let [id, len_ff, bufnr] = [1, len(from_file), bufnr('^'.each.'$')]
+		wh id <= len_ff
+			let from_file[id-1] .= '	#:'.bufnr.':'.id
+			let id += 1
+		endw
+		cal filter(from_file, 'v:val !~ ''^\s*\t#:\d\+:\d\+$''')
+		cal extend(lines, from_file)
+	endfo
+	if !hlexists('CtrlPTabExtra')
+		hi link CtrlPTabExtra Comment
+	en
+	sy match CtrlPTabExtra '\zs\t.*\ze$'
+	retu lines
+endf
+
+fu! ctrlp#line#accept(mode, str)
+	let info   = get(split(a:str, '\t#:\ze\d\+:\d\+$'), 1, 0)
+	let bufnr  = str2nr(get(split(info, ':'), 0, 0))
+	let linenr = get(split(info, ':'), 1, 0)
+	if bufnr
+		cal ctrlp#acceptfile(a:mode, fnamemodify(bufname(bufnr), ':p'), linenr)
+	en
+endf
+
+fu! ctrlp#line#id()
+	retu s:id
+endf
+"}}}
+
+" vim:fen:fdm=marker:fmr={{{,}}}:fdl=0:fdc=1:ts=2:sw=2:sts=2

bundle/git_ctrlp/autoload/ctrlp/mrufiles.vim

@@ -0,0 +1,92 @@
+" =============================================================================
+" File:          autoload/ctrlp/mrufiles.vim
+" Description:   Most Recently Used Files extension
+" Author:        Kien Nguyen <github.com/kien>
+" =============================================================================
+
+" Static variables {{{1
+fu! ctrlp#mrufiles#opts()
+	let opts = {
+		\ 'g:ctrlp_mruf_max': ['s:max', 250],
+		\ 'g:ctrlp_mruf_include': ['s:in', ''],
+		\ 'g:ctrlp_mruf_exclude': ['s:ex', ''],
+		\ 'g:ctrlp_mruf_case_sensitive': ['s:csen', 1],
+		\ 'g:ctrlp_mruf_relative': ['s:re', 0],
+		\ 'g:ctrlp_mruf_last_entered': ['s:mre', 0],
+		\ }
+	for [ke, va] in items(opts)
+		exe 'let' va[0] '=' string(exists(ke) ? eval(ke) : va[1])
+	endfo
+	let s:csen = s:csen ? '#' : '?'
+endf
+cal ctrlp#mrufiles#opts()
+fu! ctrlp#mrufiles#list(bufnr, ...) "{{{1
+	if s:locked | retu | en
+	let bufnr = a:bufnr + 0
+	if bufnr > 0
+		let fn = fnamemodify(bufname(bufnr), ':p')
+		let fn = exists('+ssl') ? tr(fn, '/', '\') : fn
+		if empty(fn) || !empty(&bt) || ( !empty(s:in) && fn !~# s:in )
+			\ || ( !empty(s:ex) && fn =~# s:ex ) || !filereadable(fn)
+			retu
+		en
+	en
+	if !exists('s:cadir') || !exists('s:cafile')
+		let s:cadir = ctrlp#utils#cachedir().ctrlp#utils#lash().'mru'
+		let s:cafile = s:cadir.ctrlp#utils#lash().'cache.txt'
+	en
+	if a:0 && a:1 == 2
+		cal ctrlp#utils#writecache([], s:cadir, s:cafile)
+		retu []
+	en
+	" Get the list
+	let mrufs = ctrlp#utils#readfile(s:cafile)
+	" Remove non-existent files
+	if a:0 && a:1 == 1
+		cal filter(mrufs, '!empty(ctrlp#utils#glob(v:val, 1)) && !s:excl(v:val)')
+		if exists('+ssl')
+			cal map(mrufs, 'tr(v:val, ''/'', ''\'')')
+			cal filter(mrufs, 'count(mrufs, v:val) == 1')
+		en
+		cal ctrlp#utils#writecache(mrufs, s:cadir, s:cafile)
+	en
+	" Return the list with the active buffer removed
+	if bufnr == -1
+		let crf = fnamemodify(bufname(winbufnr(winnr('#'))), ':p')
+		let crf = exists('+ssl') ? tr(crf, '/', '\') : crf
+		let mrufs = empty(crf) ? mrufs : filter(mrufs, 'v:val !='.s:csen.' crf')
+		if s:re
+			let cwd = exists('+ssl') ? tr(getcwd(), '/', '\') : getcwd()
+			cal filter(mrufs, '!stridx(v:val, cwd)')
+		en
+		cal map(mrufs, 'fnamemodify(v:val, '':.'')')
+		retu mrufs
+	en
+	" Remove old entry
+	cal filter(mrufs, 'v:val !='.s:csen.' fn')
+	" Insert new one
+	cal insert(mrufs, fn)
+	" Remove oldest entry or entries
+	if len(mrufs) > s:max | cal remove(mrufs, s:max, -1) | en
+	cal ctrlp#utils#writecache(mrufs, s:cadir, s:cafile)
+endf "}}}
+fu! s:excl(fn) "{{{
+	retu !empty(s:ex) && a:fn =~# s:ex
+endf "}}}
+fu! ctrlp#mrufiles#init() "{{{1
+	let s:locked = 0
+	aug CtrlPMRUF
+		au!
+		au BufReadPost,BufNewFile,BufWritePost *
+			\ cal ctrlp#mrufiles#list(expand('<abuf>', 1))
+		if s:mre
+			au BufEnter,BufUnload *
+				\ cal ctrlp#mrufiles#list(expand('<abuf>', 1))
+		en
+		au QuickFixCmdPre  *vimgrep* let s:locked = 1
+		au QuickFixCmdPost *vimgrep* let s:locked = 0
+	aug END
+endf
+"}}}
+
+" vim:fen:fdm=marker:fmr={{{,}}}:fdl=0:fdc=1:ts=2:sw=2:sts=2

bundle/git_ctrlp/autoload/ctrlp/quickfix.vim

@@ -0,0 +1,58 @@
+" =============================================================================
+" File:          autoload/ctrlp/quickfix.vim
+" Description:   Quickfix extension
+" Author:        Kien Nguyen <github.com/kien>
+" =============================================================================
+
+" Init {{{1
+if exists('g:loaded_ctrlp_quickfix') && g:loaded_ctrlp_quickfix
+	fini
+en
+let g:loaded_ctrlp_quickfix = 1
+
+let s:var_qf = {
+	\ 'init': 'ctrlp#quickfix#init()',
+	\ 'accept': 'ctrlp#quickfix#accept',
+	\ 'lname': 'quickfix',
+	\ 'sname': 'qfx',
+	\ 'type': 'line',
+	\ }
+
+let g:ctrlp_ext_vars = exists('g:ctrlp_ext_vars') && !empty(g:ctrlp_ext_vars)
+	\ ? add(g:ctrlp_ext_vars, s:var_qf) : [s:var_qf]
+
+let s:id = g:ctrlp_builtins + len(g:ctrlp_ext_vars)
+
+fu! s:lineout(dict)
+	retu printf('%s|%d:%d| %s', bufname(a:dict['bufnr']), a:dict['lnum'],
+		\ a:dict['col'], matchstr(a:dict['text'], '\s*\zs.*\S'))
+endf
+" Public {{{1
+fu! ctrlp#quickfix#init()
+	let g:ctrlp_nolimit = 1
+	if !hlexists('CtrlPqfLineCol')
+		hi link CtrlPqfLineCol Search
+	en
+	sy match CtrlPqfLineCol '|\zs\d\+:\d\+\ze|'
+	retu map(getqflist(), 's:lineout(v:val)')
+endf
+
+fu! ctrlp#quickfix#accept(mode, str)
+	let items = matchlist(a:str, '^\([^|]\+\ze\)|\(\d\+\):\(\d\+\)|')
+	let [md, filpath] = [a:mode, fnamemodify(items[1], ':p')]
+	if empty(filpath) | retu | en
+	cal ctrlp#exit()
+	let cmd = md == 't' ? 'tabe' : md == 'h' ? 'new' : md == 'v' ? 'vne'
+		\ : ctrlp#normcmd('e')
+	let cmd = cmd == 'e' && &modified ? 'hid e' : cmd
+	exe cmd ctrlp#fnesc(filpath)
+	cal cursor(items[2], items[3])
+	sil! norm! zvzz
+endf
+
+fu! ctrlp#quickfix#id()
+	retu s:id
+endf
+"}}}
+
+" vim:fen:fdm=marker:fmr={{{,}}}:fdl=0:fdc=1:ts=2:sw=2:sts=2

bundle/git_ctrlp/autoload/ctrlp/rtscript.vim

@@ -0,0 +1,51 @@
+" =============================================================================
+" File:          autoload/ctrlp/rtscript.vim
+" Description:   Runtime scripts extension
+" Author:        Kien Nguyen <github.com/kien>
+" =============================================================================
+
+" Init {{{1
+if exists('g:loaded_ctrlp_rtscript') && g:loaded_ctrlp_rtscript
+	fini
+en
+let [g:loaded_ctrlp_rtscript, g:ctrlp_newrts] = [1, 0]
+
+let s:rtscript_var = {
+	\ 'init': 'ctrlp#rtscript#init()',
+	\ 'accept': 'ctrlp#acceptfile',
+	\ 'lname': 'runtime scripts',
+	\ 'sname': 'rts',
+	\ 'type': 'path',
+	\ }
+
+let g:ctrlp_ext_vars = exists('g:ctrlp_ext_vars') && !empty(g:ctrlp_ext_vars)
+	\ ? add(g:ctrlp_ext_vars, s:rtscript_var) : [s:rtscript_var]
+
+let s:id = g:ctrlp_builtins + len(g:ctrlp_ext_vars)
+" Public {{{1
+fu! ctrlp#rtscript#init()
+	if g:ctrlp_newrts
+		\ || !( exists('g:ctrlp_rtscache') && g:ctrlp_rtscache[0] == &rtp )
+		sil! cal ctrlp#progress('Indexing...')
+		let entries = split(globpath(&rtp, '**/*.*'), "\n")
+		cal filter(entries, 'count(entries, v:val) == 1')
+		let [entries, echoed] = [ctrlp#dirnfile(entries)[1], 1]
+	el
+		let [entries, results] = g:ctrlp_rtscache[2:3]
+	en
+	let cwd = getcwd()
+	if g:ctrlp_newrts
+		\ || !( exists('g:ctrlp_rtscache') && g:ctrlp_rtscache[:1] == [&rtp, cwd] )
+		if !exists('echoed') | sil! cal ctrlp#progress('Processing...') | en
+		let results = map(copy(entries), 'fnamemodify(v:val, '':.'')')
+	en
+	let [g:ctrlp_rtscache, g:ctrlp_newrts] = [[&rtp, cwd, entries, results], 0]
+	retu results
+endf
+
+fu! ctrlp#rtscript#id()
+	retu s:id
+endf
+"}}}
+
+" vim:fen:fdm=marker:fmr={{{,}}}:fdl=0:fdc=1:ts=2:sw=2:sts=2

bundle/git_ctrlp/autoload/ctrlp/tag.vim

@@ -0,0 +1,111 @@
+" =============================================================================
+" File:          autoload/ctrlp/tag.vim
+" Description:   Tag file extension
+" Author:        Kien Nguyen <github.com/kien>
+" =============================================================================
+
+" Init {{{1
+if exists('g:loaded_ctrlp_tag') && g:loaded_ctrlp_tag
+	fini
+en
+let g:loaded_ctrlp_tag = 1
+
+let s:tag_var = {
+	\ 'init': 'ctrlp#tag#init(s:tagfiles)',
+	\ 'accept': 'ctrlp#tag#accept',
+	\ 'lname': 'tags',
+	\ 'sname': 'tag',
+	\ 'type': 'tabs',
+	\ }
+
+let g:ctrlp_ext_vars = exists('g:ctrlp_ext_vars') && !empty(g:ctrlp_ext_vars)
+	\ ? add(g:ctrlp_ext_vars, s:tag_var) : [s:tag_var]
+
+let s:id = g:ctrlp_builtins + len(g:ctrlp_ext_vars)
+" Utilities {{{1
+fu! s:nodup(items)
+	let dict = {}
+	for each in a:items
+		cal extend(dict, { each : 0 })
+	endfo
+	retu keys(dict)
+endf
+
+fu! s:findcount(str)
+	let [tg, fname] = split(a:str, '\t\+\ze[^\t]\+$')
+	let [fname, tgs] = [expand(fname, 1), taglist('^'.tg.'$')]
+	if empty(tgs) | retu [1, 1] | en
+	let [fnd, ct, pos] = [0, 0, 0]
+	for each in tgs
+		let ct += 1
+		let fulname = fnamemodify(each["filename"], ':p')
+		if stridx(fulname, fname) >= 0
+			\ && strlen(fname) + stridx(fulname, fname) == strlen(fulname)
+			let fnd += 1
+			let pos = ct
+		en
+		if fnd > 1 | brea | en
+	endfo
+	retu [fnd, pos]
+endf
+
+fu! s:filter(tags)
+	let [nr, alltags] = [0, a:tags]
+	wh 0 < 1
+		if alltags[nr] =~ '^!' && alltags[nr] !~ '^!_TAG_'
+			let nr += 1
+			con
+		en
+		if alltags[nr] =~ '^!_TAG_' && len(alltags) > nr
+			cal remove(alltags, nr)
+		el
+			brea
+		en
+	endw
+	retu alltags
+endf
+" Public {{{1
+fu! ctrlp#tag#init(tagfiles)
+	if empty(a:tagfiles) | retu [] | en
+	let [tagfiles, g:ctrlp_alltags] = [sort(s:nodup(a:tagfiles)), []]
+	for each in tagfiles
+		let alltags = s:filter(ctrlp#utils#readfile(each))
+		cal extend(g:ctrlp_alltags, alltags)
+	endfo
+	if !hlexists('CtrlPTabExtra')
+		hi link CtrlPTabExtra Comment
+	en
+	sy match CtrlPTabExtra '\zs\t.*\ze$'
+	retu g:ctrlp_alltags
+endf
+
+fu! ctrlp#tag#accept(mode, str)
+	cal ctrlp#exit()
+	let str = matchstr(a:str, '^[^\t]\+\t\+[^\t]\+\ze\t')
+	let [md, tg] = [a:mode, split(str, '^[^\t]\+\zs\t')[0]]
+	let fnd = s:findcount(str)
+	let cmds = {
+		\ 't': ['tab sp', 'tab stj'],
+		\ 'h': ['sp', 'stj'],
+		\ 'v': ['vs', 'vert stj'],
+		\ 'e': ['', 'tj'],
+		\ }
+	let cmd = fnd[0] == 1 ? cmds[md][0] : cmds[md][1]
+	let cmd = cmd == 'tj' && &modified ? 'hid '.cmd : cmd
+	let cmd = cmd =~ '^tab' ? tabpagenr('$').cmd : cmd
+	if fnd[0] == 1
+		if cmd != ''
+			exe cmd
+		en
+		exe fnd[1].'ta' tg
+	el
+		exe cmd tg
+	en
+endf
+
+fu! ctrlp#tag#id()
+	retu s:id
+endf
+"}}}
+
+" vim:fen:fdm=marker:fmr={{{,}}}:fdl=0:fdc=1:ts=2:sw=2:sts=2

bundle/git_ctrlp/autoload/ctrlp/undo.vim

@@ -0,0 +1,123 @@
+" =============================================================================
+" File:          autoload/ctrlp/undo.vim
+" Description:   Undo extension - Browse undo history (requires Vim 7.3.005+)
+" Author:        Kien Nguyen <github.com/kien>
+" =============================================================================
+
+" User Configuration {{{1
+" Enable:
+"        let g:ctrlp_extensions += ['undo']
+" Create A Command:
+"        com! CtrlPUndo cal ctrlp#init(ctrlp#undo#id())
+"}}}
+
+" Init {{{1
+if ( exists('g:loaded_ctrlp_undo') && g:loaded_ctrlp_undo )
+	\ || !( v:version > 702 && has('patch005') )
+	fini
+en
+let g:loaded_ctrlp_undo = 1
+
+let s:undo_var = {
+	\ 'init': 'ctrlp#undo#init(s:undotree)',
+	\ 'accept': 'ctrlp#undo#accept',
+	\ 'lname': 'undo',
+	\ 'sname': 'udo',
+	\ 'type': 'line',
+	\ }
+
+let g:ctrlp_ext_vars = exists('g:ctrlp_ext_vars') && !empty(g:ctrlp_ext_vars)
+	\ ? add(g:ctrlp_ext_vars, s:undo_var) : [s:undo_var]
+
+let s:id = g:ctrlp_builtins + len(g:ctrlp_ext_vars)
+" Utilities {{{1
+fu! s:flatten(tree)
+	let flatdict = {}
+	for each in a:tree
+		cal extend(flatdict, { each['seq'] : each['time'] })
+		if has_key(each, 'alt')
+			cal extend(flatdict, s:flatten(each['alt']))
+		en
+	endfo
+	retu flatdict
+endf
+
+fu! s:humantime(nr)
+	let elapsed = localtime() - a:nr
+	let mins = elapsed / 60
+	let hrs  = elapsed / 3600
+	let days = elapsed / 86400
+	let wks  = elapsed / 604800
+	let mons = elapsed / 2592000
+	let yrs  = elapsed / 31536000
+	let text = [
+		\ ' second ago',
+		\ ' seconds ago',
+		\ ' minutes ago',
+		\ ' hours ago',
+		\ ' days ago',
+		\ ' weeks ago',
+		\ ' months ago',
+		\ ' years ago',
+		\ ]
+	if yrs > 1
+		retu yrs.text[7]
+	elsei mons > 1
+		retu mons.text[6]
+	elsei wks > 1
+		retu wks.text[5]
+	elsei days > 1
+		retu days.text[4]
+	elsei hrs > 1
+		retu hrs.text[3]
+	elsei mins > 1
+		retu mins.text[2]
+	elsei elapsed == 1
+		retu elapsed.text[0]
+	elsei elapsed < 120
+		retu elapsed.text[1]
+	en
+endf
+
+fu! s:syntax()
+	for [ke, va] in items({'T': 'Directory', 'Br': 'Comment', 'Nr': 'String'})
+		if !hlexists('CtrlPUndo'.ke)
+			exe 'hi link CtrlPUndo'.ke va
+		en
+	endfo
+	sy match CtrlPUndoT '\d\+ \zs[^ ]\+\ze'
+	sy match CtrlPUndoBr '\[\|\]'
+	sy match CtrlPUndoNr '\[\d\+\]$' contains=CtrlPUndoBr
+endf
+
+fu! s:dict2list(dict)
+	let dict = map(a:dict, 's:humantime(v:val)')
+	retu map(keys(dict), 'eval(''[v:val, dict[v:val]]'')')
+endf
+
+fu! s:compval(...)
+	retu a:2[0] - a:1[0]
+endf
+" Public {{{1
+fu! ctrlp#undo#init(undo)
+	let entries = a:undo['entries']
+	if empty(entries) | retu [] | en
+	cal s:syntax()
+	let g:ctrlp_nolimit = 1
+	let entries = sort(s:dict2list(s:flatten(entries)), 's:compval')
+	retu map(entries, 'v:val[1]." [".v:val[0]."]"')
+endf
+
+fu! ctrlp#undo#accept(mode, str)
+	let undon = matchstr(a:str, '\[\zs\d\+\ze\]')
+	if empty(undon) | retu | en
+	cal ctrlp#exit()
+	exe 'u' undon
+endf
+
+fu! ctrlp#undo#id()
+	retu s:id
+endf
+"}}}
+
+" vim:fen:fdm=marker:fmr={{{,}}}:fdl=0:fdc=1:ts=2:sw=2:sts=2

bundle/git_ctrlp/autoload/ctrlp/utils.vim

@@ -0,0 +1,75 @@
+" =============================================================================
+" File:          autoload/ctrlp/utils.vim
+" Description:   Utilities
+" Author:        Kien Nguyen <github.com/kien>
+" =============================================================================
+
+" Static variables {{{1
+fu! ctrlp#utils#lash()
+	retu &ssl || !exists('+ssl') ? '/' : '\'
+endf
+let s:lash = ctrlp#utils#lash()
+
+fu! s:lash(...)
+	retu match(a:0 ? a:1 : getcwd(), '[\/]$') < 0 ? s:lash : ''
+endf
+
+fu! ctrlp#utils#opts()
+	let usrhome = $HOME.s:lash($HOME)
+	let cahome = exists('$XDG_CACHE_HOME') ? $XDG_CACHE_HOME : usrhome.'.cache'
+	let s:cache_dir = isdirectory(usrhome.'.ctrlp_cache')
+		\ ? usrhome.'.ctrlp_cache' : cahome.s:lash(cahome).'ctrlp'
+	if exists('g:ctrlp_cache_dir')
+		let s:cache_dir = expand(g:ctrlp_cache_dir, 1)
+		if isdirectory(s:cache_dir.s:lash(s:cache_dir).'.ctrlp_cache')
+			let s:cache_dir = s:cache_dir.s:lash(s:cache_dir).'.ctrlp_cache'
+		en
+	en
+endf
+cal ctrlp#utils#opts()
+" Files and Directories {{{1
+fu! ctrlp#utils#cachedir()
+	retu s:cache_dir
+endf
+
+fu! ctrlp#utils#cachefile(...)
+	let tail = a:0 ? '.'.a:1 : ''
+	let cache_file = substitute(getcwd(), '\([\/]\|^\a\zs:\)', '%', 'g').tail.'.txt'
+	retu a:0 ? cache_file : s:cache_dir.s:lash(s:cache_dir).cache_file
+endf
+
+fu! ctrlp#utils#readfile(file)
+	if filereadable(a:file)
+		let data = readfile(a:file)
+		if empty(data) || type(data) != 3
+			unl data
+			let data = []
+		en
+		retu data
+	en
+	retu []
+endf
+
+fu! ctrlp#utils#mkdir(dir)
+	if exists('*mkdir') && !isdirectory(a:dir)
+		sil! cal mkdir(a:dir, 'p')
+	en
+	retu a:dir
+endf
+
+fu! ctrlp#utils#writecache(lines, ...)
+	if isdirectory(ctrlp#utils#mkdir(a:0 ? a:1 : s:cache_dir))
+		sil! cal writefile(a:lines, a:0 >= 2 ? a:2 : ctrlp#utils#cachefile())
+		if !a:0
+			let g:ctrlp_newcache = 0
+		en
+	en
+endf
+
+fu! ctrlp#utils#glob(...)
+	let cond = v:version > 702 || ( v:version == 702 && has('patch051') )
+	retu call('glob', cond ? a:000 : [a:1])
+endf
+"}}}
+
+" vim:fen:fdm=marker:fmr={{{,}}}:fdl=0:fdc=1:ts=2:sw=2:sts=2