mirror of
https://github.com/gryf/.vim.git
synced 2025-12-18 20:10:27 +01:00
Added omnicompletion and indentation for javascript (including node.js).
Added Windows configuration.
This commit is contained in:
539
bundle/git_vim-javascript/indent/html.vim
Normal file
539
bundle/git_vim-javascript/indent/html.vim
Normal file
@@ -0,0 +1,539 @@
|
||||
" Vim indent script for HTML
|
||||
" General: "{{{
|
||||
" File: html.vim (Vimscript #2075)
|
||||
" Author: Andy Wokula <anwoku@yahoo.de>
|
||||
" Last Change: 2012 Jun 05
|
||||
" Last Changed By: Hsiaoming Yang <lepture@me.com>
|
||||
" Version: 0.8
|
||||
" Vim Version: Vim7
|
||||
" Description:
|
||||
" Improved version of the distributed html indent script, faster on a
|
||||
" range of lines.
|
||||
"
|
||||
" Customization:
|
||||
" This section is about variables you can set in your vimrc.
|
||||
"
|
||||
" - You can set the indent for the first line after <script> and <style>
|
||||
" "blocktags" (default "zero"):
|
||||
"
|
||||
" :let g:html_indent_script1 = "inc"
|
||||
" :let g:html_indent_style1 = "inc"
|
||||
"
|
||||
" VALUE MEANING
|
||||
" "zero" zero indent
|
||||
" "auto" auto indent (same indent as the blocktag)
|
||||
" "inc" auto indent + one indent step
|
||||
"
|
||||
" - Many tags increase the indent for what follows per default (see
|
||||
" "Add Indent Tags" below in this script). You can add further tags with
|
||||
"
|
||||
" :let g:html_indent_inctags = "html,body,head,tbody"
|
||||
"
|
||||
" You can also remove such tags with
|
||||
"
|
||||
" :let g:html_indent_autotags = "th,td,tr,tfoot,thead"
|
||||
"
|
||||
" Default value is empty for both variables. Note: the initial "inctags"
|
||||
" are only defined once per Vim session.
|
||||
"
|
||||
" User variables are only read when the script is sourced. To enable your
|
||||
" changes during a session, you can manually do
|
||||
" :call HtmlIndent_CheckUserSettings()
|
||||
" if you don't want to reload the html file.
|
||||
"
|
||||
" Detail:
|
||||
" Calculation of indent inside "blocktags" with "alien" content:
|
||||
" BLOCKTAG INDENT EXPR WHEN APPLICABLE
|
||||
" <script> : {customizable} if first line of block
|
||||
" : cindent(v:lnum) if attributes empty or contain "java"
|
||||
" : -1 else (vbscript, tcl, ...)
|
||||
" <style> : {customizable} if first line of block
|
||||
" : GetCSSIndent() else
|
||||
" <!-- --> : -1
|
||||
"
|
||||
" Credits:
|
||||
" indent/html.vim (2006 Jun 05) from J. Zellner
|
||||
" indent/css.vim (2006 Dec 20) from N. Weibull
|
||||
"
|
||||
" History:
|
||||
" 2011 Sep 09 added HTML5 tags (thx to J. Zuckerman)
|
||||
" 2012 Jun 05 added JavaScript Indention (thx to Hsiaoming Yang)
|
||||
" }}}
|
||||
|
||||
" Init Folklore, check user settings (2nd time ++) "{{{
|
||||
if exists("b:did_indent")
|
||||
finish
|
||||
endif
|
||||
|
||||
" Initial indent/javascript before set did_indent = 1
|
||||
ru! indent/javascript.vim
|
||||
|
||||
let b:did_indent = 1
|
||||
|
||||
setlocal indentexpr=HtmlIndent()
|
||||
setlocal indentkeys=o,O,<Return>,<>>,{,},!^F
|
||||
|
||||
let b:indent = {"lnum": -1}
|
||||
let b:undo_indent = "set inde< indk<| unlet b:indent"
|
||||
|
||||
" Load Once:
|
||||
if exists("*HtmlIndent")
|
||||
call HtmlIndent_CheckUserSettings()
|
||||
finish
|
||||
endif
|
||||
|
||||
let s:cpo_save = &cpo
|
||||
set cpo-=C
|
||||
"}}}
|
||||
|
||||
func! HtmlIndent_CheckUserSettings() "{{{
|
||||
if exists("g:html_indent_inctags")
|
||||
call s:AddITags(split(g:html_indent_inctags, ","))
|
||||
endif
|
||||
if exists("g:html_indent_autotags")
|
||||
call s:RemoveITags(split(g:html_indent_autotags, ","))
|
||||
endif
|
||||
|
||||
let indone = {"zero": 0
|
||||
\,"auto": "indent(prevnonblank(v:lnum-1))"
|
||||
\,"inc": "b:indent.blocktagind + &shiftwidth"}
|
||||
if exists("g:html_indent_script1")
|
||||
let s:js1indent = get(indone, g:html_indent_script1, indone.zero)
|
||||
endif
|
||||
if exists("g:html_indent_style1")
|
||||
let s:css1indent = get(indone, g:html_indent_style1, indone.zero)
|
||||
endif
|
||||
endfunc "}}}
|
||||
|
||||
" Init Script Vars "{{{
|
||||
let s:usestate = 1
|
||||
let s:css1indent = 0
|
||||
let s:js1indent = 0
|
||||
" not to be changed:
|
||||
let s:endtags = [0,0,0,0,0,0,0,0] " some places unused
|
||||
let s:newstate = {}
|
||||
let s:countonly = 0
|
||||
"}}}
|
||||
func! s:AddITags(taglist) "{{{
|
||||
for itag in a:taglist
|
||||
let s:indent_tags[itag] = 1
|
||||
let s:indent_tags['/'.itag] = -1
|
||||
endfor
|
||||
endfunc "}}}
|
||||
func! s:AddBlockTag(tag, id, ...) "{{{
|
||||
if !(a:id >= 2 && a:id < 2+len(s:endtags))
|
||||
return
|
||||
endif
|
||||
let s:indent_tags[a:tag] = a:id
|
||||
if a:0 == 0
|
||||
let s:indent_tags['/'.a:tag] = -a:id
|
||||
let s:endtags[a:id-2] = "</".a:tag.">"
|
||||
else
|
||||
let s:indent_tags[a:1] = -a:id
|
||||
let s:endtags[a:id-2] = a:1
|
||||
endif
|
||||
endfunc "}}}
|
||||
func! s:RemoveITags(taglist) "{{{
|
||||
" remove itags (protect blocktags from being removed)
|
||||
for itag in a:taglist
|
||||
if !has_key(s:indent_tags, itag) || s:indent_tags[itag] != 1
|
||||
continue
|
||||
endif
|
||||
unlet s:indent_tags[itag]
|
||||
if itag =~ '^\w\+$'
|
||||
unlet s:indent_tags["/".itag]
|
||||
endif
|
||||
endfor
|
||||
endfunc "}}}
|
||||
" Add Indent Tags: {{{
|
||||
if !exists("s:indent_tags")
|
||||
let s:indent_tags = {}
|
||||
endif
|
||||
|
||||
" old tags:
|
||||
call s:AddITags(['a', 'abbr', 'acronym', 'address', 'b', 'bdo', 'big',
|
||||
\ 'blockquote', 'button', 'caption', 'center', 'cite', 'code', 'colgroup',
|
||||
\ 'del', 'dfn', 'dir', 'div', 'dl', 'em', 'fieldset', 'font', 'form',
|
||||
\ 'frameset', 'h1', 'h2', 'h3', 'h4', 'h5', 'h6', 'i', 'iframe', 'ins', 'kbd',
|
||||
\ 'label', 'legend', 'map', 'menu', 'noframes', 'noscript', 'object', 'ol',
|
||||
\ 'optgroup', 'q', 's', 'samp', 'select', 'small', 'span', 'strong', 'sub',
|
||||
\ 'sup', 'table', 'textarea', 'title', 'tt', 'u', 'ul', 'var', 'th', 'td',
|
||||
\ 'tr', 'tfoot', 'thead'])
|
||||
|
||||
" tags added 2011 Sep 09 (especially HTML5 tags):
|
||||
call s:AddITags(['area', 'article', 'aside', 'audio', 'bdi', 'canvas',
|
||||
\ 'command', 'datalist', 'details', 'embed', 'figure', 'footer',
|
||||
\ 'header', 'group', 'keygen', 'mark', 'math', 'meter', 'nav', 'output',
|
||||
\ 'progress', 'ruby', 'section', 'svg', 'texture', 'time', 'video',
|
||||
\ 'wbr', 'text'])
|
||||
|
||||
"}}}
|
||||
" Add Block Tags: contain alien content "{{{
|
||||
call s:AddBlockTag('pre', 2)
|
||||
call s:AddBlockTag('script', 3)
|
||||
call s:AddBlockTag('style', 4)
|
||||
call s:AddBlockTag('<!--', 5, '-->')
|
||||
"}}}
|
||||
|
||||
func! s:CountITags(...) "{{{
|
||||
|
||||
" relative indent steps for current line [unit &sw]:
|
||||
let s:curind = 0
|
||||
" relative indent steps for next line [unit &sw]:
|
||||
let s:nextrel = 0
|
||||
|
||||
if a:0==0
|
||||
let s:block = s:newstate.block
|
||||
let tmpline = substitute(s:curline, '<\zs\/\=\w\+\>\|<!--\|-->', '\=s:CheckTag(submatch(0))', 'g')
|
||||
if s:block == 3
|
||||
let s:newstate.scripttype = s:GetScriptType(matchstr(tmpline, '\C.*<SCRIPT\>\zs[^>]*'))
|
||||
endif
|
||||
let s:newstate.block = s:block
|
||||
else
|
||||
let s:block = 0 " assume starting outside of a block
|
||||
let s:countonly = 1 " don't change state
|
||||
let tmpline = substitute(s:altline, '<\zs\/\=\w\+\>\|<!--\|-->', '\=s:CheckTag(submatch(0))', 'g')
|
||||
let s:countonly = 0
|
||||
endif
|
||||
endfunc "}}}
|
||||
func! s:CheckTag(itag) "{{{
|
||||
" "tag" or "/tag" or "<!--" or "-->"
|
||||
let ind = get(s:indent_tags, a:itag)
|
||||
if ind == -1
|
||||
" closing tag
|
||||
if s:block != 0
|
||||
" ignore itag within a block
|
||||
return "foo"
|
||||
endif
|
||||
if s:nextrel == 0
|
||||
let s:curind -= 1
|
||||
else
|
||||
let s:nextrel -= 1
|
||||
endif
|
||||
" if s:curind >= 1
|
||||
" let s:curind -= 1
|
||||
" else
|
||||
" let s:nextrel -= 1
|
||||
" endif
|
||||
elseif ind == 1
|
||||
" opening tag
|
||||
if s:block != 0
|
||||
return "foo"
|
||||
endif
|
||||
let s:nextrel += 1
|
||||
elseif ind != 0
|
||||
" block-tag (opening or closing)
|
||||
return s:Blocktag(a:itag, ind)
|
||||
endif
|
||||
" else ind==0 (other tag found): keep indent
|
||||
return "foo" " no matter
|
||||
endfunc "}}}
|
||||
func! s:Blocktag(blocktag, ind) "{{{
|
||||
if a:ind > 0
|
||||
" a block starts here
|
||||
if s:block != 0
|
||||
" already in a block (nesting) - ignore
|
||||
" especially ignore comments after other blocktags
|
||||
return "foo"
|
||||
endif
|
||||
let s:block = a:ind " block type
|
||||
if s:countonly
|
||||
return "foo"
|
||||
endif
|
||||
let s:newstate.blocklnr = v:lnum
|
||||
" save allover indent for the endtag
|
||||
let s:newstate.blocktagind = b:indent.baseindent + (s:nextrel + s:curind) * &shiftwidth
|
||||
if a:ind == 3
|
||||
return "SCRIPT" " all except this must be lowercase
|
||||
" line is to be checked again for the type attribute
|
||||
endif
|
||||
else
|
||||
let s:block = 0
|
||||
" we get here if starting and closing block-tag on same line
|
||||
endif
|
||||
return "foo"
|
||||
endfunc "}}}
|
||||
func! s:GetScriptType(str) "{{{
|
||||
if a:str == "" || a:str =~ "java"
|
||||
return "javascript"
|
||||
else
|
||||
return ""
|
||||
endif
|
||||
endfunc "}}}
|
||||
|
||||
func! s:FreshState(lnum) "{{{
|
||||
" Look back in the file (lines 1 to a:lnum-1) to calc a state for line
|
||||
" a:lnum. A state is to know ALL relevant details about the lines
|
||||
" 1..a:lnum-1, initial calculating (here!) can be slow, but updating is
|
||||
" fast (incremental).
|
||||
" State:
|
||||
" lnum last indented line == prevnonblank(a:lnum - 1)
|
||||
" block = 0 a:lnum located within special tag: 0:none, 2:<pre>,
|
||||
" 3:<script>, 4:<style>, 5:<!--
|
||||
" baseindent use this indent for line a:lnum as a start - kind of
|
||||
" autoindent (if block==0)
|
||||
" scripttype = '' type attribute of a script tag (if block==3)
|
||||
" blocktagind indent for current opening (get) and closing (set)
|
||||
" blocktag (if block!=0)
|
||||
" blocklnr lnum of starting blocktag (if block!=0)
|
||||
" inattr line {lnum} starts with attributes of a tag
|
||||
let state = {}
|
||||
let state.lnum = prevnonblank(a:lnum - 1)
|
||||
let state.scripttype = ""
|
||||
let state.blocktagind = -1
|
||||
let state.block = 0
|
||||
let state.baseindent = 0
|
||||
let state.blocklnr = 0
|
||||
let state.inattr = 0
|
||||
|
||||
if state.lnum == 0
|
||||
return state
|
||||
endif
|
||||
|
||||
" Heuristic:
|
||||
" remember startline state.lnum
|
||||
" look back for <pre, </pre, <script, </script, <style, </style tags
|
||||
" remember stopline
|
||||
" if opening tag found,
|
||||
" assume a:lnum within block
|
||||
" else
|
||||
" look back in result range (stopline, startline) for comment
|
||||
" \ delimiters (<!--, -->)
|
||||
" if comment opener found,
|
||||
" assume a:lnum within comment
|
||||
" else
|
||||
" assume usual html for a:lnum
|
||||
" if a:lnum-1 has a closing comment
|
||||
" look back to get indent of comment opener
|
||||
" FI
|
||||
|
||||
" look back for blocktag
|
||||
call cursor(a:lnum, 1)
|
||||
let [stopline, stopcol] = searchpos('\c<\zs\/\=\%(pre\>\|script\>\|style\>\)', "bW")
|
||||
" fugly ... why isn't there searchstr()
|
||||
let tagline = tolower(getline(stopline))
|
||||
let blocktag = matchstr(tagline, '\/\=\%(pre\>\|script\>\|style\>\)', stopcol-1)
|
||||
if stopline > 0 && blocktag[0] != "/"
|
||||
" opening tag found, assume a:lnum within block
|
||||
let state.block = s:indent_tags[blocktag]
|
||||
if state.block == 3
|
||||
let state.scripttype = s:GetScriptType(matchstr(tagline, '\>[^>]*', stopcol))
|
||||
endif
|
||||
let state.blocklnr = stopline
|
||||
" check preceding tags in the line:
|
||||
let s:altline = tagline[: stopcol-2]
|
||||
call s:CountITags(1)
|
||||
let state.blocktagind = indent(stopline) + (s:curind + s:nextrel) * &shiftwidth
|
||||
return state
|
||||
elseif stopline == state.lnum
|
||||
" handle special case: previous line (= state.lnum) contains a
|
||||
" closing blocktag which is preceded by line-noise;
|
||||
" blocktag == "/..."
|
||||
let swendtag = match(tagline, '^\s*</') >= 0
|
||||
if !swendtag
|
||||
let [bline, bcol] = searchpos('<'.blocktag[1:].'\>', "bW")
|
||||
let s:altline = tolower(getline(bline)[: bcol-2])
|
||||
call s:CountITags(1)
|
||||
let state.baseindent = indent(bline) + (s:nextrel+s:curline) * &shiftwidth
|
||||
return state
|
||||
endif
|
||||
endif
|
||||
|
||||
" else look back for comment
|
||||
call cursor(a:lnum, 1)
|
||||
let [comline, comcol, found] = searchpos('\(<!--\)\|-->', 'bpW', stopline)
|
||||
if found == 2
|
||||
" comment opener found, assume a:lnum within comment
|
||||
let state.block = 5
|
||||
let state.blocklnr = comline
|
||||
" check preceding tags in the line:
|
||||
let s:altline = tolower(getline(comline)[: comcol-2])
|
||||
call s:CountITags(1)
|
||||
let state.blocktagind = indent(comline) + (s:curind + s:nextrel) * &shiftwidth
|
||||
return state
|
||||
endif
|
||||
|
||||
" else within usual html
|
||||
let s:altline = tolower(getline(state.lnum))
|
||||
" check a:lnum-1 for closing comment (we need indent from the opening line)
|
||||
let comcol = stridx(s:altline, '-->')
|
||||
if comcol >= 0
|
||||
call cursor(state.lnum, comcol+1)
|
||||
let [comline, comcol] = searchpos('<!--', 'bW')
|
||||
if comline == state.lnum
|
||||
let s:altline = s:altline[: comcol-2]
|
||||
else
|
||||
let s:altline = tolower(getline(comline)[: comcol-2])
|
||||
endif
|
||||
call s:CountITags(1)
|
||||
let state.baseindent = indent(comline) + (s:nextrel+s:curline) * &shiftwidth
|
||||
return state
|
||||
" TODO check tags that follow "-->"
|
||||
endif
|
||||
|
||||
" else no comments
|
||||
call s:CountITags(1)
|
||||
let state.baseindent = indent(state.lnum) + s:nextrel * &shiftwidth
|
||||
" line starts with end tag
|
||||
let swendtag = match(s:altline, '^\s*</') >= 0
|
||||
if !swendtag
|
||||
let state.baseindent += s:curind * &shiftwidth
|
||||
endif
|
||||
return state
|
||||
endfunc "}}}
|
||||
|
||||
func! s:Alien2() "{{{
|
||||
" <pre> block
|
||||
return -1
|
||||
endfunc "}}}
|
||||
func! s:Alien3() "{{{
|
||||
" <script> javascript
|
||||
if prevnonblank(v:lnum-1) == b:indent.blocklnr
|
||||
" indent for the first line after <script>
|
||||
return eval(s:js1indent)
|
||||
endif
|
||||
if b:indent.scripttype == "javascript"
|
||||
"return cindent(v:lnum)
|
||||
return GetJavascriptIndent()
|
||||
else
|
||||
return -1
|
||||
endif
|
||||
endfunc "}}}
|
||||
func! s:Alien4() "{{{
|
||||
" <style>
|
||||
if prevnonblank(v:lnum-1) == b:indent.blocklnr
|
||||
" indent for first content line
|
||||
return eval(s:css1indent)
|
||||
endif
|
||||
return s:CSSIndent()
|
||||
endfunc
|
||||
|
||||
func! s:CSSIndent() "{{{
|
||||
" adopted $VIMRUNTIME/indent/css.vim
|
||||
if getline(v:lnum) =~ '^\s*[*}]'
|
||||
return cindent(v:lnum)
|
||||
endif
|
||||
let minline = b:indent.blocklnr
|
||||
let pnum = s:css_prevnoncomment(v:lnum - 1, minline)
|
||||
if pnum <= minline
|
||||
" < is to catch errors
|
||||
" indent for first content line after comments
|
||||
return eval(s:css1indent)
|
||||
endif
|
||||
let ind = indent(pnum) + s:css_countbraces(pnum, 1) * &sw
|
||||
let pline = getline(pnum)
|
||||
if pline =~ '}\s*$'
|
||||
let ind -= (s:css_countbraces(pnum, 0) - (pline =~ '^\s*}')) * &sw
|
||||
endif
|
||||
return ind
|
||||
endfunc "}}}
|
||||
func! s:css_prevnoncomment(lnum, stopline) "{{{
|
||||
" caller starts from a line a:lnum-1 that is not a comment
|
||||
let lnum = prevnonblank(a:lnum)
|
||||
let ccol = match(getline(lnum), '\*/')
|
||||
if ccol < 0
|
||||
return lnum
|
||||
endif
|
||||
call cursor(lnum, ccol+1)
|
||||
let lnum = search('/\*', 'bW', a:stopline)
|
||||
if indent(".") == virtcol(".")-1
|
||||
return prevnonblank(lnum-1)
|
||||
else
|
||||
return lnum
|
||||
endif
|
||||
endfunc "}}}
|
||||
func! s:css_countbraces(lnum, count_open) "{{{
|
||||
let brs = substitute(getline(a:lnum),'[''"].\{-}[''"]\|/\*.\{-}\*/\|/\*.*$\|[^{}]','','g')
|
||||
let n_open = 0
|
||||
let n_close = 0
|
||||
for brace in split(brs, '\zs')
|
||||
if brace == "{"
|
||||
let n_open += 1
|
||||
elseif brace == "}"
|
||||
if n_open > 0
|
||||
let n_open -= 1
|
||||
else
|
||||
let n_close += 1
|
||||
endif
|
||||
endif
|
||||
endfor
|
||||
return a:count_open ? n_open : n_close
|
||||
endfunc "}}}
|
||||
|
||||
"}}}
|
||||
func! s:Alien5() "{{{
|
||||
" <!-- -->
|
||||
return -1
|
||||
endfunc "}}}
|
||||
|
||||
func! HtmlIndent() "{{{
|
||||
let s:curline = tolower(getline(v:lnum))
|
||||
|
||||
let s:newstate = {}
|
||||
let s:newstate.lnum = v:lnum
|
||||
|
||||
" is the first non-blank in the line the start of a tag?
|
||||
let swendtag = match(s:curline, '^\s*</') >= 0
|
||||
|
||||
if prevnonblank(v:lnum-1) == b:indent.lnum && s:usestate
|
||||
" use state (continue from previous line)
|
||||
else
|
||||
" start over (know nothing)
|
||||
let b:indent = s:FreshState(v:lnum)
|
||||
endif
|
||||
|
||||
if b:indent.block >= 2
|
||||
" within block
|
||||
let endtag = s:endtags[b:indent.block-2]
|
||||
let blockend = stridx(s:curline, endtag)
|
||||
if blockend >= 0
|
||||
" block ends here
|
||||
let s:newstate.block = 0
|
||||
" calc indent for REST OF LINE (may start more blocks):
|
||||
let s:curline = strpart(s:curline, blockend+strlen(endtag))
|
||||
call s:CountITags()
|
||||
if swendtag && b:indent.block != 5
|
||||
let indent = b:indent.blocktagind + s:curind * &shiftwidth
|
||||
let s:newstate.baseindent = indent + s:nextrel * &shiftwidth
|
||||
else
|
||||
let indent = s:Alien{b:indent.block}()
|
||||
let s:newstate.baseindent = b:indent.blocktagind + s:nextrel * &shiftwidth
|
||||
endif
|
||||
call extend(b:indent, s:newstate, "force")
|
||||
return indent
|
||||
else
|
||||
" block continues
|
||||
" indent this line with alien method
|
||||
let indent = s:Alien{b:indent.block}()
|
||||
call extend(b:indent, s:newstate, "force")
|
||||
return indent
|
||||
endif
|
||||
else
|
||||
" not within a block - within usual html
|
||||
" if < 2 then always 0
|
||||
let s:newstate.block = b:indent.block
|
||||
call s:CountITags()
|
||||
if swendtag
|
||||
let indent = b:indent.baseindent + s:curind * &shiftwidth
|
||||
let s:newstate.baseindent = indent + s:nextrel * &shiftwidth
|
||||
else
|
||||
let indent = b:indent.baseindent
|
||||
let s:newstate.baseindent = indent + (s:curind + s:nextrel) * &shiftwidth
|
||||
endif
|
||||
call extend(b:indent, s:newstate, "force")
|
||||
return indent
|
||||
endif
|
||||
|
||||
endfunc "}}}
|
||||
|
||||
" check user settings (first time), clear cpo, Modeline: {{{1
|
||||
|
||||
" DEBUG:
|
||||
com! -nargs=* IndHtmlLocal <args>
|
||||
|
||||
call HtmlIndent_CheckUserSettings()
|
||||
|
||||
let &cpo = s:cpo_save
|
||||
unlet s:cpo_save
|
||||
|
||||
" vim:set fdm=marker ts=8:
|
||||
330
bundle/git_vim-javascript/indent/javascript.vim
Normal file
330
bundle/git_vim-javascript/indent/javascript.vim
Normal file
@@ -0,0 +1,330 @@
|
||||
" Vim indent file
|
||||
" Language: Javascript
|
||||
" Maintainer: Darrick Wiebe <darrick at innatesoftware.com>
|
||||
" URL: http://github.com/pangloss/vim-javascript
|
||||
" Version: 1.0.0
|
||||
" Last Change: August 31, 2009
|
||||
" Acknowledgement: Based off of vim-ruby maintained by Nikolai Weibull http://vim-ruby.rubyforge.org
|
||||
|
||||
" 0. Initialization {{{1
|
||||
" =================
|
||||
|
||||
" Only load this indent file when no other was loaded.
|
||||
if exists("b:did_indent")
|
||||
finish
|
||||
endif
|
||||
let b:did_indent = 1
|
||||
|
||||
setlocal nosmartindent
|
||||
|
||||
" Now, set up our indentation expression and keys that trigger it.
|
||||
setlocal indentexpr=GetJavascriptIndent()
|
||||
setlocal indentkeys=0{,0},0),0],!^F,o,O,e
|
||||
|
||||
" Only define the function once.
|
||||
if exists("*GetJavascriptIndent")
|
||||
finish
|
||||
endif
|
||||
|
||||
let s:cpo_save = &cpo
|
||||
set cpo&vim
|
||||
|
||||
" 1. Variables {{{1
|
||||
" ============
|
||||
|
||||
" Regex of syntax group names that are or delimit string or are comments.
|
||||
let s:syng_strcom = 'javaScript\%(String\|RegexpString\|CommentTodo\|LineComment\|Comment\|DocComment\)'
|
||||
|
||||
" Regex of syntax group names that are strings.
|
||||
let s:syng_string = 'javaScript\%(RegexpString\)'
|
||||
|
||||
" Regex of syntax group names that are strings or documentation.
|
||||
let s:syng_multiline = 'javaScriptDocComment\|javaScriptComment'
|
||||
|
||||
" Expression used to check whether we should skip a match with searchpair().
|
||||
let s:skip_expr = "synIDattr(synID(line('.'),col('.'),1),'name') =~ '".s:syng_strcom."'"
|
||||
|
||||
let s:line_term = '\s*\%(\%(\/\/\).*\)\=$'
|
||||
|
||||
" Regex that defines continuation lines, not including (, {, or [.
|
||||
let s:continuation_regex = '\%([\\*+/.:]\|\%(<%\)\@<![=-]\|\W[|&?]\|||\|&&\)' . s:line_term
|
||||
|
||||
" Regex that defines continuation lines.
|
||||
" TODO: this needs to deal with if ...: and so on
|
||||
let s:msl_regex = '\%([\\*+/.:([]\|\%(<%\)\@<![=-]\|\W[|&?]\|||\|&&\)' . s:line_term
|
||||
|
||||
let s:one_line_scope_regex = '\<\%(if\|else\|for\|while\)\>[^{;]*' . s:line_term
|
||||
|
||||
" Regex that defines blocks.
|
||||
let s:block_regex = '\%({\)\s*\%(|\%([*@]\=\h\w*,\=\s*\)\%(,\s*[*@]\=\h\w*\)*|\)\=' . s:line_term
|
||||
|
||||
" 2. Auxiliary Functions {{{1
|
||||
" ======================
|
||||
|
||||
" Check if the character at lnum:col is inside a string, comment, or is ascii.
|
||||
function s:IsInStringOrComment(lnum, col)
|
||||
return synIDattr(synID(a:lnum, a:col, 1), 'name') =~ s:syng_strcom
|
||||
endfunction
|
||||
|
||||
" Check if the character at lnum:col is inside a string.
|
||||
function s:IsInString(lnum, col)
|
||||
return synIDattr(synID(a:lnum, a:col, 1), 'name') =~ s:syng_string
|
||||
endfunction
|
||||
|
||||
" Check if the character at lnum:col is inside a multi-line comment.
|
||||
function s:IsInMultilineComment(lnum, col)
|
||||
return synIDattr(synID(a:lnum, a:col, 1), 'name') =~ s:syng_multiline
|
||||
endfunction
|
||||
|
||||
" Find line above 'lnum' that isn't empty, in a comment, or in a string.
|
||||
function s:PrevNonBlankNonString(lnum)
|
||||
let in_block = 0
|
||||
let lnum = prevnonblank(a:lnum)
|
||||
while lnum > 0
|
||||
" Go in and out of blocks comments as necessary.
|
||||
" If the line isn't empty (with opt. comment) or in a string, end search.
|
||||
let line = getline(lnum)
|
||||
if line =~ '/\*'
|
||||
if in_block
|
||||
let in_block = 0
|
||||
else
|
||||
break
|
||||
endif
|
||||
elseif !in_block && line =~ '\*/'
|
||||
let in_block = 1
|
||||
elseif !in_block && line !~ '^\s*\%(//\).*$' && !(s:IsInStringOrComment(lnum, 1) && s:IsInStringOrComment(lnum, strlen(line)))
|
||||
break
|
||||
endif
|
||||
let lnum = prevnonblank(lnum - 1)
|
||||
endwhile
|
||||
return lnum
|
||||
endfunction
|
||||
|
||||
" Find line above 'lnum' that started the continuation 'lnum' may be part of.
|
||||
function s:GetMSL(lnum, in_one_line_scope)
|
||||
" Start on the line we're at and use its indent.
|
||||
let msl = a:lnum
|
||||
let lnum = s:PrevNonBlankNonString(a:lnum - 1)
|
||||
while lnum > 0
|
||||
" If we have a continuation line, or we're in a string, use line as MSL.
|
||||
" Otherwise, terminate search as we have found our MSL already.
|
||||
let line = getline(lnum)
|
||||
let col = match(line, s:msl_regex) + 1
|
||||
if (col > 0 && !s:IsInStringOrComment(lnum, col)) || s:IsInString(lnum, strlen(line))
|
||||
let msl = lnum
|
||||
else
|
||||
" Don't use lines that are part of a one line scope as msl unless the
|
||||
" flag in_one_line_scope is set to 1
|
||||
"
|
||||
if a:in_one_line_scope
|
||||
break
|
||||
end
|
||||
let msl_one_line = s:Match(lnum, s:one_line_scope_regex)
|
||||
if msl_one_line == 0
|
||||
break
|
||||
endif
|
||||
endif
|
||||
let lnum = s:PrevNonBlankNonString(lnum - 1)
|
||||
endwhile
|
||||
return msl
|
||||
endfunction
|
||||
|
||||
" Check if line 'lnum' has more opening brackets than closing ones.
|
||||
function s:LineHasOpeningBrackets(lnum)
|
||||
let open_0 = 0
|
||||
let open_2 = 0
|
||||
let open_4 = 0
|
||||
let line = getline(a:lnum)
|
||||
let pos = match(line, '[][(){}]', 0)
|
||||
while pos != -1
|
||||
if !s:IsInStringOrComment(a:lnum, pos + 1)
|
||||
let idx = stridx('(){}[]', line[pos])
|
||||
if idx % 2 == 0
|
||||
let open_{idx} = open_{idx} + 1
|
||||
else
|
||||
let open_{idx - 1} = open_{idx - 1} - 1
|
||||
endif
|
||||
endif
|
||||
let pos = match(line, '[][(){}]', pos + 1)
|
||||
endwhile
|
||||
return (open_0 > 0) . (open_2 > 0) . (open_4 > 0)
|
||||
endfunction
|
||||
|
||||
function s:Match(lnum, regex)
|
||||
let col = match(getline(a:lnum), a:regex) + 1
|
||||
return col > 0 && !s:IsInStringOrComment(a:lnum, col) ? col : 0
|
||||
endfunction
|
||||
|
||||
function s:IndentWithContinuation(lnum, ind, width)
|
||||
" Set up variables to use and search for MSL to the previous line.
|
||||
let p_lnum = a:lnum
|
||||
let lnum = s:GetMSL(a:lnum, 1)
|
||||
let line = getline(lnum)
|
||||
|
||||
" If the previous line wasn't a MSL and is continuation return its indent.
|
||||
" TODO: the || s:IsInString() thing worries me a bit.
|
||||
if p_lnum != lnum
|
||||
if s:Match(p_lnum,s:continuation_regex)||s:IsInString(p_lnum,strlen(line))
|
||||
return a:ind
|
||||
endif
|
||||
endif
|
||||
|
||||
" Set up more variables now that we know we aren't continuation bound.
|
||||
let msl_ind = indent(lnum)
|
||||
|
||||
" If the previous line ended with [*+/.-=], start a continuation that
|
||||
" indents an extra level.
|
||||
if s:Match(lnum, s:continuation_regex)
|
||||
if lnum == p_lnum
|
||||
return msl_ind + a:width
|
||||
else
|
||||
return msl_ind
|
||||
endif
|
||||
endif
|
||||
|
||||
return a:ind
|
||||
endfunction
|
||||
|
||||
function s:InOneLineScope(lnum)
|
||||
let msl = s:GetMSL(a:lnum, 1)
|
||||
if msl > 0 && s:Match(msl, s:one_line_scope_regex)
|
||||
return msl
|
||||
endif
|
||||
return 0
|
||||
endfunction
|
||||
|
||||
function s:ExitingOneLineScope(lnum)
|
||||
let msl = s:GetMSL(a:lnum, 1)
|
||||
if msl > 0
|
||||
" if the current line is in a one line scope ..
|
||||
if s:Match(msl, s:one_line_scope_regex)
|
||||
return 0
|
||||
else
|
||||
let prev_msl = s:GetMSL(msl - 1, 1)
|
||||
if s:Match(prev_msl, s:one_line_scope_regex)
|
||||
return prev_msl
|
||||
endif
|
||||
endif
|
||||
endif
|
||||
return 0
|
||||
endfunction
|
||||
|
||||
" 3. GetJavascriptIndent Function {{{1
|
||||
" =========================
|
||||
|
||||
function GetJavascriptIndent()
|
||||
" 3.1. Setup {{{2
|
||||
" ----------
|
||||
|
||||
" Set up variables for restoring position in file. Could use v:lnum here.
|
||||
let vcol = col('.')
|
||||
|
||||
" 3.2. Work on the current line {{{2
|
||||
" -----------------------------
|
||||
|
||||
" Get the current line.
|
||||
let line = getline(v:lnum)
|
||||
let ind = -1
|
||||
|
||||
" If we got a closing bracket on an empty line, find its match and indent
|
||||
" according to it. For parentheses we indent to its column - 1, for the
|
||||
" others we indent to the containing line's MSL's level. Return -1 if fail.
|
||||
let col = matchend(line, '^\s*[]})]')
|
||||
if col > 0 && !s:IsInStringOrComment(v:lnum, col)
|
||||
call cursor(v:lnum, col)
|
||||
let bs = strpart('(){}[]', stridx(')}]', line[col - 1]) * 2, 2)
|
||||
if searchpair(escape(bs[0], '\['), '', bs[1], 'bW', s:skip_expr) > 0
|
||||
if line[col-1]==')' && col('.') != col('$') - 1
|
||||
let ind = virtcol('.')-1
|
||||
else
|
||||
let ind = indent(s:GetMSL(line('.'), 0))
|
||||
endif
|
||||
endif
|
||||
return ind
|
||||
endif
|
||||
|
||||
" If we are in a multi-line comment, cindent does the right thing.
|
||||
if s:IsInMultilineComment(v:lnum, 1)
|
||||
return cindent(v:lnum)
|
||||
endif
|
||||
|
||||
" 3.3. Work on the previous line. {{{2
|
||||
" -------------------------------
|
||||
|
||||
" If the line is empty and the previous nonblank line was a multi-line
|
||||
" comment, use that comment's indent. Deduct one char to account for the
|
||||
" space in ' */'.
|
||||
let nonblank_lnum = prevnonblank(v:lnum - 1)
|
||||
if line =~ '^\s*$' && s:IsInMultilineComment(nonblank_lnum, 1)
|
||||
return indent(nonblank_lnum) - 1
|
||||
endif
|
||||
|
||||
" Find a non-blank, non-multi-line string line above the current line.
|
||||
let lnum = s:PrevNonBlankNonString(v:lnum - 1)
|
||||
|
||||
" If the line is empty and inside a string, use the previous line.
|
||||
if line =~ '^\s*$' && lnum != nonblank_lnum
|
||||
return indent(prevnonblank(v:lnum))
|
||||
endif
|
||||
|
||||
" At the start of the file use zero indent.
|
||||
if lnum == 0
|
||||
return 0
|
||||
endif
|
||||
|
||||
" Set up variables for current line.
|
||||
let line = getline(lnum)
|
||||
let ind = indent(lnum)
|
||||
|
||||
" If the previous line ended with a block opening, add a level of indent.
|
||||
if s:Match(lnum, s:block_regex)
|
||||
return indent(s:GetMSL(lnum, 0)) + &sw
|
||||
endif
|
||||
|
||||
" If the previous line contained an opening bracket, and we are still in it,
|
||||
" add indent depending on the bracket type.
|
||||
if line =~ '[[({]'
|
||||
let counts = s:LineHasOpeningBrackets(lnum)
|
||||
if counts[0] == '1' && searchpair('(', '', ')', 'bW', s:skip_expr) > 0
|
||||
if col('.') + 1 == col('$')
|
||||
return ind + &sw
|
||||
else
|
||||
return virtcol('.')
|
||||
endif
|
||||
elseif counts[1] == '1' || counts[2] == '1'
|
||||
return ind + &sw
|
||||
else
|
||||
call cursor(v:lnum, vcol)
|
||||
end
|
||||
endif
|
||||
|
||||
" 3.4. Work on the MSL line. {{{2
|
||||
" --------------------------
|
||||
|
||||
let ind_con = ind
|
||||
let ind = s:IndentWithContinuation(lnum, ind_con, &sw)
|
||||
|
||||
" }}}2
|
||||
"
|
||||
"
|
||||
let ols = s:InOneLineScope(lnum)
|
||||
if ols > 0
|
||||
let ind = ind + &sw
|
||||
else
|
||||
let ols = s:ExitingOneLineScope(lnum)
|
||||
while ols > 0 && ind > 0
|
||||
let ind = ind - &sw
|
||||
let ols = s:InOneLineScope(ols - 1)
|
||||
endwhile
|
||||
endif
|
||||
|
||||
return ind
|
||||
endfunction
|
||||
|
||||
" }}}1
|
||||
|
||||
let &cpo = s:cpo_save
|
||||
unlet s:cpo_save
|
||||
|
||||
" vim:set sw=2 sts=2 ts=8 noet:
|
||||
|
||||
Reference in New Issue
Block a user