From 18fcf3ca6935948493f9ccc4f0038039b2a40c16 Mon Sep 17 00:00:00 2001
From: gryf <gryf73@gmail.com>
Date: Tue, 6 Nov 2018 22:04:58 +0100
Subject: [PATCH] Added profanity ebuild

---
 dev-libs/libmesode/Manifest              |  1 +
 dev-libs/libmesode/libmesode-9999.ebuild | 50 +++++++++++++++++
 net-im/profanity/Manifest                |  1 +
 net-im/profanity/profanity-9999.ebuild   | 68 ++++++++++++++++++++++++
 4 files changed, 120 insertions(+)
 create mode 100644 dev-libs/libmesode/Manifest
 create mode 100644 dev-libs/libmesode/libmesode-9999.ebuild
 create mode 100644 net-im/profanity/Manifest
 create mode 100644 net-im/profanity/profanity-9999.ebuild

diff --git a/dev-libs/libmesode/Manifest b/dev-libs/libmesode/Manifest
new file mode 100644
index 0000000..de75c1d
--- /dev/null
+++ b/dev-libs/libmesode/Manifest
@@ -0,0 +1 @@
+EBUILD libmesode-9999.ebuild 946 BLAKE2B 0f90fc6a6757aa8b239dca0509454f67d14424a901a18e95b519c18879cd8b9ea561f496eefdd45aadb9656676e3fc3cb25cb5b6225d835f3feba21a119f0b33 SHA512 e0b2f9261807810e684e6091fb2d59b6f339bf13b399e7bac72a2b80f7b890aa297455822ba37ca6bf2940b5deb2f5925be9c7ac8fb95559ae67e70f72c9d47d
diff --git a/dev-libs/libmesode/libmesode-9999.ebuild b/dev-libs/libmesode/libmesode-9999.ebuild
new file mode 100644
index 0000000..e4681fb
--- /dev/null
+++ b/dev-libs/libmesode/libmesode-9999.ebuild
@@ -0,0 +1,50 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit autotools git-r3
+
+DESCRIPTION="Fork of libstrophe for use with Profanity XMPP Client"
+HOMEPAGE="https://github.com/boothj5/libmesode"
+EGIT_REPO_URI="https://github.com/boothj5/${PN}.git"
+
+LICENSE="|| ( MIT GPL-3 )"
+SLOT="0"
+KEYWORDS=""
+IUSE="doc examples libressl +ssl static-libs test"
+
+RDEPEND="dev-libs/expat
+	ssl? (
+		!libressl? ( dev-libs/openssl:0= )
+		libressl? ( dev-libs/libressl:0= )
+	)"
+DEPEND="${RDEPEND}
+	doc? ( app-doc/doxygen )"
+
+src_prepare() {
+	default
+	eautoreconf
+}
+
+src_configure() {
+	# shellcheck disable=SC2207
+	local myeconf=(
+		$(use_enable ssl tls)
+		$(use_enable test static)
+		$(use_enable static-libs static)
+	)
+	econf "${myeconf[@]}"
+}
+src_compile() {
+	default
+	if use doc; then
+		doxygen || die
+		HTML_DOCS=( docs/html/* )
+	fi
+}
+
+src_install() {
+	default
+	use examples && dodoc -r examples
+}
diff --git a/net-im/profanity/Manifest b/net-im/profanity/Manifest
new file mode 100644
index 0000000..82355dc
--- /dev/null
+++ b/net-im/profanity/Manifest
@@ -0,0 +1 @@
+EBUILD profanity-9999.ebuild 1586 BLAKE2B f11387787c4ea4fa5f5cf9a3bde4edd1608e7b9bb4d6233b66f92a11f8f2a610ad8ba536f9f7b5414dc4314676d1c9625b105ac032f6598e4c6586dea5c33716 SHA512 9f1c286f52805de7e3c58cb6b9a6400d0b2cda73c514fba45e3873f97e7edb9aa5f76d36982d50492856a274878d74cdcf1f1cc7ac898e5a935ca217f12b9520
diff --git a/net-im/profanity/profanity-9999.ebuild b/net-im/profanity/profanity-9999.ebuild
new file mode 100644
index 0000000..c63f4a6
--- /dev/null
+++ b/net-im/profanity/profanity-9999.ebuild
@@ -0,0 +1,68 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python2_7 )
+
+inherit autotools eutils git-r3 python-single-r1
+
+DESCRIPTION="A console based XMPP client inspired by Irssi"
+HOMEPAGE="http://profanity.im"
+EGIT_REPO_URI="https://github.com/boothj5/profanity.git"
+RESTRICT="mirror"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS=""
+IUSE="+c-plugins icons +largefile libnotify +otr pgp +plugins python-plugins test +themes xscreensaver"
+REQUIRED_USE="c-plugins? ( plugins )
+	python-plugins? ( plugins ${PYTHON_REQUIRED_USE} )"
+
+CDEPEND="dev-libs/glib:2
+	net-misc/curl
+	sys-apps/util-linux:0
+	sys-libs/ncurses:0[unicode]
+	sys-libs/readline:0
+	|| (
+		>=dev-libs/libmesode-0.9.1[ssl]
+		>=dev-libs/libstrophe-0.9.1[ssl,xml]
+	)
+	icons? ( >=x11-libs/gtk+-2.24.10:2 )
+	libnotify? ( x11-libs/libnotify )
+	otr? ( net-libs/libotr )
+	pgp? ( app-crypt/gpgme )
+	python-plugins? ( ${PYTHON_DEPS} )
+	xscreensaver? ( x11-libs/libXScrnSaver )"
+DEPEND="${CDEPEND}
+	virtual/pkgconfig
+	test? ( dev-util/cmocka )"
+RDEPEND="${CDEPEND}
+	libnotify? ( virtual/notification-daemon )"
+
+src_prepare() {
+	default
+	eautoreconf
+}
+
+src_configure() {
+	# shellcheck disable=SC2207
+	local myeconf=(
+		$(use_enable c-plugins)
+		$(use_enable icons)
+		$(use_enable largefile)
+		$(use_enable libnotify notifications)
+		$(use_enable otr)
+		$(use_enable pgp)
+		$(use_enable plugins)
+		$(use_enable python-plugins)
+		$(use_with themes)
+		$(use_with xscreensaver)
+	)
+	econf "${myeconf[@]}" || die "econf failed"
+}
+
+src_install() {
+	default
+	prune_libtool_files
+}