gui-apps/input-leap added

2026-08-23 04:01:52 +02:00 · 2026-08-21 07:30:23 +02:00
parent f174a23a25
commit f8d8432df4
4 changed files with 189 additions and 0 deletions
@@ -0,0 +1,4 @@
+DIST input-leap-3.0.3.tar.gz 1764202 BLAKE2B fbafa19481025660fba282580054fd0b9dc4d87553fcf495acfa15b0283e4f60fa15a904ba3ef516a8325aa3e99118aaf95343e741df5b57da30b958612f7965 SHA512 bcfad3938c2a6082ca3d2e083147002f0b870e81026580cc7f655ea9c43b707552e188a0fb93669466d037569e89983b35e16a272cb313e40039f2abac98f444
+EBUILD input-leap-3.0.3-r10.ebuild 1765 BLAKE2B 0d1b5a8d09e440c975314b6a42f42f726058acdfb251b9d3f101f90a96a9c0fb2176d3aca4b515f1129057e3551730d03932dafc77c257eef129c16b4b2ef6e0 SHA512 a2180f4c382695729b16114622ab1fcbb53f443de479f6244c9978151749a9d6335aa001d0eaab568b16ca5b189465454e07b8a3604beb0a341ad228d95bc90a
+EBUILD input-leap-9999.ebuild 1765 BLAKE2B 0d1b5a8d09e440c975314b6a42f42f726058acdfb251b9d3f101f90a96a9c0fb2176d3aca4b515f1129057e3551730d03932dafc77c257eef129c16b4b2ef6e0 SHA512 a2180f4c382695729b16114622ab1fcbb53f443de479f6244c9978151749a9d6335aa001d0eaab568b16ca5b189465454e07b8a3604beb0a341ad228d95bc90a
+MISC metadata.xml 334 BLAKE2B f9676570d302d59e3ef2a4c70cc27d7594acebacdb55cf3c91dfd10ea97d59ab3f88c902f4b6ddcaf44d400a473c9d712a0e48baf1c076cec69db0bc8817248d SHA512 10c48513d6fa6dd7c987e8576bfadea12865516218323796878f148b2365111aa89644c0d4d370d3c0ed34522b471c11d5005dc1bb53d1cef9cc623b7bfce690
@@ -0,0 +1,87 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+VIRTUALX_REQUIRED="manual"
+inherit cmake virtualx xdg
+
+if [[ ${PV} == *9999* ]]; then
+	EGIT_REPO_URI="https://github.com/input-leap/input-leap.git"
+	inherit git-r3
+else
+	SRC_URI="https://github.com/input-leap/input-leap/archive/refs/tags/v${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~x86"
+fi
+
+DESCRIPTION="Share a mouse and keyboard between computers (fork of Barrier)"
+HOMEPAGE="https://github.com/input-leap/input-leap"
+
+LICENSE="GPL-2"
+SLOT="0"
+IUSE="gui test +wayland +X"
+REQUIRED_USE="|| ( wayland X )"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	dev-libs/openssl:0=
+	gui? (
+		dev-qt/qtbase:6[gui,network,widgets]
+		net-dns/avahi[mdnsresponder-compat]
+	)
+	wayland? (
+		dev-libs/glib:2
+		dev-libs/libei
+		dev-libs/libportal:=
+		x11-libs/libxkbcommon
+	)
+	X? (
+		x11-libs/libICE
+		x11-libs/libSM
+		x11-libs/libX11
+		x11-libs/libXext
+		x11-libs/libXi
+		x11-libs/libXinerama
+		x11-libs/libXrandr
+		x11-libs/libXtst
+	)
+"
+DEPEND="
+	${RDEPEND}
+	x11-base/xorg-proto
+	test? ( dev-cpp/gtest )
+"
+BDEPEND="
+	virtual/pkgconfig
+	gui? ( dev-qt/qttools:6[linguist] )
+	test? ( X? ( ${VIRTUALX_DEPEND} ) )
+"
+
+DOCS=(
+	ChangeLog
+	README.md
+	doc/${PN}.conf.example{,-advanced,-basic}
+)
+
+src_configure() {
+	local REV="${EGIT_VERSION:-00000000}"
+	local mycmakeargs=(
+		-DINPUTLEAP_BUILD_GUI=$(usex gui)
+		-DINPUTLEAP_BUILD_LIBEI=$(usex wayland)
+		-DINPUTLEAP_BUILD_TESTS=$(usex test)
+		-DINPUTLEAP_BUILD_X11=$(usex X)
+		-DINPUTLEAP_REVISION="${REV:0:8}"
+		-DINPUTLEAP_USE_EXTERNAL_GTEST=ON
+	)
+	cmake_src_configure
+}
+
+src_test() {
+	"${BUILD_DIR}"/bin/unittests || die
+
+	if use X; then
+		virtx "${BUILD_DIR}"/bin/integtests
+	else
+		"${BUILD_DIR}"/bin/integtests || die
+	fi
+}
@@ -0,0 +1,87 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+VIRTUALX_REQUIRED="manual"
+inherit cmake virtualx xdg
+
+if [[ ${PV} == *9999* ]]; then
+	EGIT_REPO_URI="https://github.com/input-leap/input-leap.git"
+	inherit git-r3
+else
+	SRC_URI="https://github.com/input-leap/input-leap/archive/refs/tags/v${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~x86"
+fi
+
+DESCRIPTION="Share a mouse and keyboard between computers (fork of Barrier)"
+HOMEPAGE="https://github.com/input-leap/input-leap"
+
+LICENSE="GPL-2"
+SLOT="0"
+IUSE="gui test +wayland +X"
+REQUIRED_USE="|| ( wayland X )"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	dev-libs/openssl:0=
+	gui? (
+		dev-qt/qtbase:6[gui,network,widgets]
+		net-dns/avahi[mdnsresponder-compat]
+	)
+	wayland? (
+		dev-libs/glib:2
+		dev-libs/libei
+		dev-libs/libportal:=
+		x11-libs/libxkbcommon
+	)
+	X? (
+		x11-libs/libICE
+		x11-libs/libSM
+		x11-libs/libX11
+		x11-libs/libXext
+		x11-libs/libXi
+		x11-libs/libXinerama
+		x11-libs/libXrandr
+		x11-libs/libXtst
+	)
+"
+DEPEND="
+	${RDEPEND}
+	x11-base/xorg-proto
+	test? ( dev-cpp/gtest )
+"
+BDEPEND="
+	virtual/pkgconfig
+	gui? ( dev-qt/qttools:6[linguist] )
+	test? ( X? ( ${VIRTUALX_DEPEND} ) )
+"
+
+DOCS=(
+	ChangeLog
+	README.md
+	doc/${PN}.conf.example{,-advanced,-basic}
+)
+
+src_configure() {
+	local REV="${EGIT_VERSION:-00000000}"
+	local mycmakeargs=(
+		-DINPUTLEAP_BUILD_GUI=$(usex gui)
+		-DINPUTLEAP_BUILD_LIBEI=$(usex wayland)
+		-DINPUTLEAP_BUILD_TESTS=$(usex test)
+		-DINPUTLEAP_BUILD_X11=$(usex X)
+		-DINPUTLEAP_REVISION="${REV:0:8}"
+		-DINPUTLEAP_USE_EXTERNAL_GTEST=ON
+	)
+	cmake_src_configure
+}
+
+src_test() {
+	"${BUILD_DIR}"/bin/unittests || die
+
+	if use X; then
+		virtx "${BUILD_DIR}"/bin/integtests
+	else
+		"${BUILD_DIR}"/bin/integtests || die
+	fi
+}
@@ -0,0 +1,11 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="person">
+		<email>chewi@gentoo.org</email>
+		<name>James Le Cuirot</name>
+	</maintainer>
+	<upstream>
+		<remote-id type="github">input-leap/input-leap</remote-id>
+	</upstream>
+</pkgmetadata>