mirror of
https://github.com/gryf/pentadactyl-pm.git
synced 2025-12-23 21:12:27 +01:00
f36748338b
Files like vimperator.vim, javascript.vim, and vimperatorrc.example might fit better in a "contrib" directory. It's not clear whether there should be vimperator/contrib and muttator/contrib directories or a single liberator/contrib directory. The Makefile.common doesn't include these files in the bundle, and so it doesn't seem like a bad idea to package them in a single liberator/contrib directory with a CONTENTS or README file giving a ToC for the directory.
111 lines
5.8 KiB
VimL
111 lines
5.8 KiB
VimL
" Vim syntax file
|
|
" Language: VIMperator configuration file
|
|
" Maintainer: Doug Kearns <dougkearns@gmail.com>
|
|
" Last Change: 2008 Dec 31
|
|
"
|
|
" To use this file, copy it to ~/.vim/syntax/vimperator.vim and create
|
|
" ~/.vim/ftdetect/vimperator.vim with contents like:
|
|
"
|
|
" au BufNewFile,BufRead *.vimp setl filetype=vimperator
|
|
" au BufNewFile,BufRead */{.,_}{vimperator,muttator}rc setl filetype=vimperator
|
|
|
|
if exists("b:current_syntax")
|
|
finish
|
|
endif
|
|
|
|
let s:cpo_save = &cpo
|
|
set cpo&vim
|
|
|
|
syn include @javascriptTop syntax/javascript.vim
|
|
unlet b:current_syntax
|
|
|
|
syn include @cssTop syntax/css.vim
|
|
unlet b:current_syntax
|
|
|
|
syn match vimperatorCommandStart "\%(^\s*:\=\)\@<=" nextgroup=vimperatorCommand,vimperatorAutoCmd
|
|
|
|
syn keyword vimperatorCommand ab[breviate] ab[clear] addo[ns] b[uffer] ba[ck] bd[elete] beep bf[irst] bl[ast] bma[rk] bmarks
|
|
\ bn[ext] bN[ext] bp[revious] br[ewind] buffers bun[load] bw[ipeout] ca[bbrev] cabc[lear] cd chd[ir] colo[rscheme] cuna[bbrev]
|
|
\ cm[ap] cmapc[lear] cno[remap] comc[lear] com[mand] cu[nmap] do[autocmd] doautoa[ll] delbm[arks] delc[ommand] delmac[ros]
|
|
\ delm[arks] delqm[arks] dels[tyle] dia[log] dl downl[oads] e[dit] ec[ho] echoe[rr] echom[sg] em[enu] exe[cute] exu[sage]
|
|
\ fini[sh] files fo[rward] fw h[elp] ha[rdcopy] hi[ghlight] hist[ory] hs ia[bbrev] iabc[lear] im[ap] imapc[lear] ino[remap]
|
|
\ iuna[bbrev] iu[nmap] javas[cript] ju[mps] js let loadplugins lpl ls macros ma[rk] map mapc[lear] marks mes[sages]
|
|
\ mkv[imperatorrc] no[remap] noh[lsearch] norm[al] o[pen] optionu[sage] pa[geinfo] pagest[yle] pc[lose] pl[ay] pref[erences]
|
|
\ prefs pw[d] q[uit] qa[ll] qma[rk] qmarks quita[ll] re[draw] re[load] reloada[ll] res[tart] run runt[ime] sty[le] sav[eas]
|
|
\ sb[ar] sb[open] sbcl[ose] scrip[tnames] se[t] setg[lobal] setl[ocal] sideb[ar] so[urce] st[op] tN[ext] t[open] tab
|
|
\ tabde[tach] tabd[uplicate] tabN[ext] tabc[lose] tabe[dit] tabfir[st] tabl[ast] tabm[ove] tabn[ext] tabnew tabo[nly] tabopen
|
|
\ tabp[revious] tabr[ewind] tabs time tn[ext] tp[revious] u[ndo] una[bbreviate] undoa[ll] unl[et] unm[ap] ve[rsion]
|
|
\ vie[wsource] viu[sage] w[rite] wc[lose] win[open] winc[lose] wine[dit] wo[pen] wqa[ll] wq xa[ll] zo[om]
|
|
\ contained
|
|
|
|
syn match vimperatorCommand "!" contained
|
|
|
|
syn keyword vimperatorAutoCmd au[tocmd] contained nextgroup=vimperatorAutoEventList skipwhite
|
|
|
|
syn keyword vimperatorAutoEvent BookmarkAdd DOMLoad LocationChange PageLoadPre PageLoad ShellCmdPost VimperatorEnter
|
|
\ VimperatorLeavePre VimperatorLeave
|
|
\ contained
|
|
|
|
syn match vimperatorAutoEventList "\(\a\+,\)*\a\+" contained contains=vimperatorAutoEvent
|
|
|
|
syn region vimperatorSet matchgroup=vimperatorCommand start="\%(^\s*:\=\)\@<=\<\%(setl\%[ocal]\|setg\%[lobal]\|set\=\)\=\>"
|
|
\ end="$" keepend oneline contains=vimperatorOption,vimperatorString
|
|
|
|
syn keyword vimperatorOption activate act alfc albc cdpath cd complete cpt defsearch ds editor extendedhinttags eht eventignore ei
|
|
\ followhints fh guioptions go helpfile hf hintmatching hm hs hinttags ht hinttimeout hto history hi laststatus ls lbc lfc
|
|
\ messages msgs newtab nextpattern pageinfo pa popups pps previewheight pvh previouspattern runtimepath rtp scroll scr shell
|
|
\ sh shellcmdflag shcf showstatuslinks ssli showtabline stal suggestengines titlestring urlseparator verbose vbs t_vb wildcase
|
|
\ wic wildignore wig wildmode wim wildoptions wop wordseparators wsp
|
|
\ contained nextgroup=vimperatorSetMod
|
|
|
|
" toggle options
|
|
syn match vimperatorOption "\<\%(no\|inv\)\=\%(errorbells\|eb\|exrc\|ex\|focuscontent\|fc\|fullscreen\|fs\|ignorecase\|ic\)\>!\="
|
|
\ contained nextgroup=vimperatorSetMod
|
|
syn match vimperatorOption "\<\%(no\|inv\)\=\%(incsearch\|is\|insertmode\|im\|hlsearch\|hls\|linksearch\|lks\)\>!\="
|
|
\ contained nextgroup=vimperatorSetMod
|
|
syn match vimperatorOption "\<\%(no\|inv\)\=\%(loadplugins\|lpl\|more\|online\|preload\|showmode\|smd\|smartcase\|scs\)\>!\="
|
|
\ contained nextgroup=vimperatorSetMod
|
|
syn match vimperatorOption "\<\%(no\|inv\)\=\%(online\|visualbell\|vb\|usermode\|um\)\>!\="
|
|
\ contained nextgroup=vimperatorSetMod
|
|
|
|
syn match vimperatorSetMod "\%(\<[a-z_]\+\)\@<=&" contained
|
|
|
|
syn region vimperatorJavaScript start="\%(^\s*\%(javascript\|js\)\s\+\)\@<=" end="$" contains=@javascriptTop keepend oneline
|
|
syn region vimperatorJavaScript matchgroup=vimperatorJavascriptDelimiter
|
|
\ start="\%(^\s*\%(javascript\|js\)\s\+\)\@<=<<\s*\z(\h\w*\)"hs=s+2 end="^\z1$" contains=@javascriptTop fold
|
|
|
|
let s:cssRegionStart = '\%(^\s*sty\%[le]!\=\s\+\%(-\%(n\|name\)\%(\s\+\|=\)\S\+\s\+\)\=[^-]\S\+\s\+\)\@<='
|
|
execute 'syn region vimperatorCss start="' . s:cssRegionStart . '" end="$" contains=@cssTop keepend oneline'
|
|
execute 'syn region vimperatorCss matchgroup=vimperatorCssDelimiter'
|
|
\ 'start="' . s:cssRegionStart . '<<\s*\z(\h\w*\)"hs=s+2 end="^\z1$" contains=@cssTop fold'
|
|
|
|
syn match vimperatorNotation "<[0-9A-Za-z-]\+>"
|
|
|
|
syn match vimperatorComment +".*$+ contains=vimperatorTodo,@Spell
|
|
syn keyword vimperatorTodo FIXME NOTE TODO XXX contained
|
|
|
|
syn region vimperatorString start="\z(["']\)" end="\z1" skip="\\\\\|\\\z1" oneline
|
|
|
|
syn match vimperatorLineComment +^\s*".*$+ contains=vimperatorTodo,@Spell
|
|
|
|
" NOTE: match vim.vim highlighting group names
|
|
hi def link vimperatorAutoCmd vimperatorCommand
|
|
hi def link vimperatorAutoEvent Type
|
|
hi def link vimperatorCommand Statement
|
|
hi def link vimperatorComment Comment
|
|
hi def link vimperatorJavascriptDelimiter Delimiter
|
|
hi def link vimperatorCssDelimiter Delimiter
|
|
hi def link vimperatorNotation Special
|
|
hi def link vimperatorLineComment Comment
|
|
hi def link vimperatorOption PreProc
|
|
hi def link vimperatorSetMod vimperatorOption
|
|
hi def link vimperatorString String
|
|
hi def link vimperatorTodo Todo
|
|
|
|
let b:current_syntax = "vimperator"
|
|
|
|
let &cpo = s:cpo_save
|
|
unlet s:cpo_save
|
|
|
|
" vim: tw=130 et ts=4 sw=4:
|