configure: updates as reported by 'autoupdate'

Some macros have evolved, so this patch brings the appropriate updates:
 - AC_OUTPUT(...) is now split in AC_CONFIG_FILES(...) and AC_OUTPUT, took
the opportunity to sort the list of files so it is easier to maintain

 - the macro AC_DECL_SYS_SIGLIST is now replaced by the more generic
AC_CHECK_DECLS([sys_siglist]), but as it turns out that we're not using it,
the check was just removed

 - autoconf assumes that AC_TYPE_SIGNAL is deprecated because the type was
fixed since C89, but as we expect to still run on old hardware, we keep the
macro given by autoupdate on our side for when Autoconf will stop providing
the macro

Signed-off-by: Christophe CURIS <christophe.curis@free.fr>

configure.ac

@@ -78,7 +78,7 @@ AC_PROG_CC
 WM_PROG_CC_C11
 AC_PROG_LN_S
 AC_PROG_GCC_TRADITIONAL
-AC_PROG_LIBTOOL
+LT_INIT
 
 
 dnl Debugging Options
@@ -376,13 +376,12 @@ AC_CHECK_HEADERS(fcntl.h limits.h sys/ioctl.h libintl.h poll.h malloc.h ctype.h
 
 dnl Checks for typedefs, structures, and compiler characteristics.
 dnl ==============================================================
-AC_DECL_SYS_SIGLIST
 AC_C_CONST
 AC_C_INLINE
 WM_C_NORETURN
 AC_TYPE_SIZE_T
 AC_TYPE_PID_T
-AC_TYPE_SIGNAL
+WM_TYPE_SIGNAL
 
 
 dnl pkg-config
@@ -902,22 +901,6 @@ dnl ======================================
 WM_CFLAGS_GCC_OPTION_POSTPONED
 
 
-AC_OUTPUT(Makefile po/Makefile util/Makefile util/po/Makefile test/Makefile \
-	WINGs/Makefile WINGs/WINGs/Makefile WINGs/Documentation/Makefile \
-	WINGs/Examples/Makefile WINGs/Resources/Makefile WINGs/Tests/Makefile \
-	WINGs/Extras/Makefile WINGs/po/Makefile \
-	wmlib/Makefile wrlib/Makefile wrlib/tests/Makefile \
-	src/Makefile src/wconfig.h \
-	doc/Makefile doc/sk/Makefile doc/cs/Makefile \
-	doc/ru/Makefile \
-	WindowMaker/Makefile WindowMaker/Backgrounds/Makefile \
-	WindowMaker/Defaults/Makefile WindowMaker/IconSets/Makefile \
-	WindowMaker/Icons/Makefile WindowMaker/Pixmaps/Makefile \
-	WindowMaker/Styles/Makefile WindowMaker/Themes/Makefile \
-	WPrefs.app/Makefile WPrefs.app/tiff/Makefile WPrefs.app/xpm/Makefile \
-	WPrefs.app/po/Makefile )
-
-
 dnl Output some helpful data for compiling wraster and WINGs/WUtil apps
 dnl ===================================================================
 
@@ -934,6 +917,39 @@ AC_SUBST(inc_search_path)
 dnl
 dnl Spit out the configuration
 dnl ==========================
+AC_CONFIG_FILES(
+    Makefile
+
+    dnl WRaster Library
+    wrlib/Makefile
+    wrlib/tests/Makefile
+
+    dnl WINGs toolkit
+    WINGs/Makefile WINGs/WINGs/Makefile WINGs/po/Makefile
+    WINGs/Documentation/Makefile WINGs/Resources/Makefile WINGs/Extras/Makefile
+    WINGs/Examples/Makefile WINGs/Tests/Makefile
+
+    dnl Window Maker's core
+    src/Makefile src/wconfig.h po/Makefile
+    doc/Makefile doc/sk/Makefile doc/cs/Makefile doc/ru/Makefile
+    WindowMaker/Makefile WindowMaker/Backgrounds/Makefile
+    WindowMaker/Defaults/Makefile WindowMaker/IconSets/Makefile
+    WindowMaker/Icons/Makefile WindowMaker/Pixmaps/Makefile
+    WindowMaker/Styles/Makefile WindowMaker/Themes/Makefile
+
+    dnl Preference GUI
+    WPrefs.app/Makefile WPrefs.app/po/Makefile
+    WPrefs.app/tiff/Makefile WPrefs.app/xpm/Makefile
+
+    dnl Command-line utilities
+    util/Makefile util/po/Makefile
+
+    dnl Misceleanous stuff
+    wmlib/Makefile
+    test/Makefile
+)
+
+AC_OUTPUT
 
 if test "x$MOFILES" = "x"; then
 	mof=None

m4/windowmaker.m4

@@ -244,3 +244,25 @@ AS_CASE([$wm_cv_func_open_nofollow],
             AC_MSG_WARN([flag O_NOFOLLOW is not defined on your platform])],
     [CPPFLAGS="$CPPFLAGS $wm_cv_func_open_nofollow"])
 ])
+
+
+# WM_TYPE_SIGNAL
+# --------------
+#
+# Check the return type for the function 'signal'
+# Autoconf now claims we can assume the type is 'void' as it is in the C89 standard,
+# but as Window Maker is supposed to be lightweight enough for old machines, we
+# prefer to keep the check for portability
+AC_DEFUN_ONCE([WM_TYPE_SIGNAL],
+[AC_CACHE_CHECK([return type of signal handlers], [wm_cv_type_signal],
+    [AC_COMPILE_IFELSE(
+        [AC_LANG_PROGRAM([#include <sys/types.h>
+#include <signal.h>
+],
+            [return *(signal (0, 0)) (0) == 1;])],
+        [wm_cv_type_signal=int],
+        [wm_cv_type_signal=void])dnl
+    ])
+AC_DEFINE_UNQUOTED([RETSIGTYPE], [$wm_cv_type_signal],
+    [Define as the return type of signal handlers (`int' or `void')])dnl
+])